So fügen Sie mehrere Bilder stapelweise in Ihr Word-Dokument ein

In diesem Artikel möchten wir Ihnen die Möglichkeit bieten, mehrere Bilder stapelweise in Ihr Word-Dokument einzufügen.

Sie können sich beim Arbeiten mit Bildern in Word wohl fühlen. Sobald Sie ein Bild in ein Dokument eingefügt haben, müssen Sie möglicherweise die Größe manuell ändern oder den Namen eingeben. Wie wäre es mit einem Makro, um die Aufgabe automatisch auszuführen?

Das Makro, das wir Ihnen vorstellen werden, kann folgende Funktionen ausführen:

1. Erstens wird die genaue Anzahl der Bilder eingefügt, die Sie auf jeder Seite angeben.
2. Zweitens wird der Name unter jedem Bild eingefügt.
3. Drittens wird die Größe der Bilder entsprechend den von Ihnen eingegebenen Größen geändert.

Schauen wir uns nun an, wie wir es zum Laufen bringen.

Batch Einfügen mehrerer Bilder in das Dokument

1. Ordnen Sie zunächst alle Bilder so an, dass sie unter demselben Ordner eingefügt werden.
2. Drücken Sie dann „Alt + F11“, um den VBA-Editor in Word aufzurufen.
3. Klicken Sie anschließend auf "Normal".
4. Klicken Sie dann in der Menüleiste auf "Einfügen".
5. Und wählen Sie im Dropdown-Menü "Modul".
6. Öffnen Sie das Modul durch Doppelklick und fügen Sie die folgenden Codes ein:

Sub InsertSpecificNumberOfPictureForEachPage()
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim objInlineShape As InlineShape
  Dim nResponse As Integer
  Dim strPictureNumber As Integer
  Dim strPictureSize As String
  Dim n As Integer  

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
  
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With

  strFile = Dir(StrFolder & "*.*", vbNormal)
  strPictureNumber = InputBox("Input the number of the picture for each page", "Picture Number", "For exemple: 1")
  n = 1  

  While strFile <> ""
    Selection.InlineShapes.AddPicture FileName:=StrFolder & strFile, LinkToFile:=False, SaveWithDocument:=True
    Selection.TypeParagraph
    Selection.Collapse Direction:=wdCollapsEnd
    Selection.TypeText Text:=Left(strFile, InStrRev(strFile, ".") - 1)
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
    If ActiveDocument.InlineShapes.Count = strPictureNumber * n Then
      Selection.InsertNewPage
      Selection.TypeBackspace
      n = n + 1
    End If
    Selection.TypeParagraph
    strFile = Dir()
  Wend

  For Each objInlineShape In ActiveDocument.InlineShapes
    objInlineShape.Select
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
  Next objInlineShape

  nResponse = MsgBox("Do you want to resize all pictures?", 4, "Resize Picture")
  If nResponse = 6 Then
    strPictureSize = InputBox("Input the height and width of the picture, seperated by comma", "Height and Width", "For exemple:500,500")
    For Each objInlineShape In ActiveDocument.InlineShapes
      objInlineShape.Height = Split(strPictureSize, ",")(0)
      objInlineShape.Width = Split(strPictureSize, ",")(1)
    Next objInlineShape
  End If
End Sub

7. Klicken Sie dann auf "Ausführen" oder drücken Sie "F5".
8. Während Sie das Makro ausführen, wird das Fenster "Durchsuchen" angezeigt. Wählen Sie einfach den Ordner aus, in dem Sie Bilder in Schritt 1 aufbewahren, und klicken Sie auf „OK“.
9. Geben Sie als Nächstes im Feld "Bildnummer" eine Zahl ein, die die Gesamtzahl der gewünschten Bilder auf einer einzelnen Seite darstellt. Und klicken Sie auf "OK", um fortzufahren.
10. Klicken Sie im Feld "Bildgröße ändern" auf "Ja", um die Größe aller Bilder zu ändern, und auf "Nein", um sie abzubrechen.
11. Geben Sie nun im Feld "Höhe und Breite" Werte ein und verwenden Sie das Komma zum Trennen. Denken Sie daran, zuerst die Höhe und dann die Breite einzugeben. Nach dem Komma ist kein Leerzeichen.
12. Klicken Sie ebenfalls auf "OK", um fortzufahren.

Jetzt gibt es 2 Bilder auf einer Seite und jedes hat seinen Namen darunter. Hier ist das Ergebnis:

Behalten Sie die Datenintegrität im Auge

Es besteht immer das Risiko, dass Daten verloren gehen oder irgendwie kompromittiert werden. Dies bedeutet, dass wir die Datenintegrität regelmäßig überprüfen müssen. Und sobald wir Anzeichen dafür finden WortschadenDer beste Weg, um Daten wiederherzustellen, ist ein Reparaturwerkzeug.

Einführung des Autors:

Vera Chen ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich Excel-Wiederherstellung , pdf Reparatur von Softwareprodukten. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX