2 Methoden zum Stapeln Löschen aller Kontakte ohne E-Mail-Adresse in Ihrem Outlook

Wenn Sie feststellen, dass einige Kontakte in Ihrem Outlook keine E-Mail-Adresse haben, möchten Sie möglicherweise jeden Kontaktordner verarbeiten, um alle diese Kontakte zu löschen. Dieser post wird 2 Mittel mit Ihnen teilen.

Möglicherweise haben Sie viele Kontakte in Ihrem Outlook und einige von ihnen haben keine E-Mail-Adresse. Wenn Sie der Meinung sind, dass sie nicht mehr nützlich sind, müssen Sie hoffen, alle Kontakte ohne E-Mail-Adresse zu löschen. Standardmäßig können Sie sie mithilfe der Sofort-Suche finden und dann manuell löschen, wie bei Methode 1 beschrieben. Dies ist jedoch etwas langwierig. Daher werden wir Ihnen in Methode 2 einen weiteren effizienteren Weg zeigen.

Methode 1: Manuelles Löschen nach dem Finden von Kontakten ohne E-Mail-Adresse

1. Für astart Drücken Sie die Tasten „Strg + 3“, um auf den Bereich „Kontakte“ zuzugreifen.
2. Klicken Sie dann in das Suchfeld.
3. Klicken Sie anschließend im angezeigten Menüband "Suchen" auf "Alle Kontaktelemente".
4. Klicken Sie anschließend auf "Hat Adresse"> "Hat E-Mail-Adresse".
5. Danach wird dem Suchfeld das Kriterium "NICHT E-Mail-Adressen: = []" hinzugefügt. Sie müssen das "NICHT" entfernen.
6. Anschließend werden alle Kontakte ohne E-Mail-Adresse aufgelistet.
7. Jetzt sollten Sie Kontakte in den Suchergebnissen manuell auswählen, da Ihre Kontaktgruppen ebenfalls in der Liste enthalten sein müssen.
8. Drücken Sie abschließend die Taste „Entf“, um alle ausgewählten Kontakte zu löschen.

Methode 2: Batch Löschen aller Kontakte ohne E-Mail-Adresse mit VBA

1. Tippen Sie zunächst auf „Alt + F11“, um den VBA-Editor in Outlook zu starten.
2. Kopieren Sie im neuen Bildschirm den folgenden VBA-Code in ein Modul.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Klicken Sie später in die Unterroutine "BatchDeleteAllContactsWithoutEmailAddress".
4. Drücken Sie schließlich "F5", um dieses Makro auszulösen.
5. Wenn der Vorgang abgeschlossen ist, erhalten Sie eine Meldung zu den Ergebnissen (siehe Abbildung unten).
6. Alle Kontakte ohne E-Mail-Adresse wurden in den Ordner "Gelöschte Objekte" verschoben.

Halten Sie sich von allen potenziellen Risiken fern

Outlook kann durch eine Vielzahl von Faktoren beschädigt werden, z. B. Viren, Benutzerfehler, Softwarefehler sowie Hardwarefehler. Sie müssen zögern, Outlook-Schäden zu erleiden, daher müssen Sie all diese potenziellen Risiken in Schach halten. Beispielsweise müssen Sie eine leistungsstarke Antivirensoftware auf Ihrem PC bereitstellen. Außerdem müssen Sie Ihre Outlook-Daten regelmäßig sichern. Zu guter Letzt sollten Sie ein robustes und zuverlässiges Reparaturwerkzeug vorbereiten, z DataNumen Outlook Repair. Es kann Ihr Problem beheben korrupte PST Datei mit Leichtigkeit.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich SQL Server Korruption und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX