Entfernen von Anhängen aus veralteten Kalenderelementen in Ihrem Outlook

Jetzt teilen:

Wenn Sie Anhänge von veralteten Terminen und Besprechungen in Ihrem Outlook entfernen möchten, können Sie diesen Artikel lesen. Hier zeigen wir Ihnen, wie Sie es in einem Rutsch realisieren können.

Um die Größe Ihrer Outlook-Datei zu reduzieren, wird dringend empfohlen, alte Elemente zu bereinigen. Dies kann durch die eingebaute „AutoArchive“-Funktion realisiert werden, die die alten Elemente in regelmäßigen Abständen automatisch löschen kann. Einige Benutzer möchten jedoch lediglich die Anhänge in den alten Elementen löschen, ohne dass dies Auswirkungen auf die Elemente selbst hat. Im Folgenden zeigen wir Ihnen, wie Sie Anhänge aus alten Kalendereinträgen in großen Mengen entfernen.

Batch-Entfernung von Anhängen aus alten Kalenderelementen in Ihrem Outlook

Batch-Entfernung von Anhängen aus veralteten Kalenderelementen

  1. Rufen Sie zunächst den Outlook VBA-Editor mit „Alt + F11“ auf.
  2. Kopieren Sie dann im Fenster „Microsoft Visual Basic für Applikationen“ den VBA-Code in ein Modul.
Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

VBA-Code – Batch-Entfernung von Anhängen aus veralteten Kalenderelementen

  1. Klicken Sie anschließend auf das Makro „BatchDeleteAttachmentsOfOldCalendarItems“.
  2. Drücken Sie abschließend die Taste „F5“, um dieses Makro auszuführen.
  3. Wenn das Makro abgeschlossen ist, können Sie alle Ihre Outlook-Kalender überprüfen.
  4. Outlook muss alle Anhänge der Kalendereinträge gelöscht haben, die älter als 2 Monate sind.Anhänge von veralteten Kalenderelementen entfernt

Bewältigen Sie beschädigte Outlook-Dateien

Sind Sie schon einmal auf eine Beschädigung von Outlook gestoßen? Wie entsorgt man es normalerweise? In den meisten Fällen würden Sie zunächst das Tool zum Reparieren des Posteingangs ausprobieren – scanpst. Im Falle eines schwerwiegenden PST-Schadens kann Ihnen das integrierte Dienstprogramm jedoch nicht weiterhelfen. Daher wird empfohlen, ein erfahreneres und leistungsfähigeres Tool eines Drittanbieters in der Nähe aufzubewahren, z DataNumen Outlook Repair.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich SQL-Reparatur und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX

Jetzt teilen:

Kommentare sind geschlossen.