Jak szybko wykluczyć oryginalnych odbiorców „DW” podczas korzystania z opcji „Odpowiedz wszystkim” w programie Outlook

W przypadku korzystania z opcji „Odpowiedz wszystkim” odpowiadająca wiadomość e-mail będzie zawierała również odbiorców „DW” oryginalnej wiadomości e-mail w polu „DW”. Jeśli jednak chcesz wykluczyć tego typu odbiorców, możesz skorzystać z metody przedstawionej w tym artykule.

Czasami chcesz odpowiedzieć na wiadomość e-mail do pierwotnego nadawcy i odbiorców „Do”. W tym scenariuszu na pewno pomyślisz o użyciu opcji „Odpowiedz wszystkim”. Jednak w ten sposób, jeśli oryginalna wiadomość ma również odbiorców „DW”, wiadomość e-mail „Odpowiedz wszystkim” automatycznie skopiuje odbiorców „DW” do pola „DW”. Jeśli nie chcesz na nie odpowiadać, musisz je ręcznie usunąć, co jest nieco kłopotliwe. Poniżej nauczymy Cię, jak umożliwić programowi Outlook automatyczne wykonanie tego zgodnie z Twoimi potrzebami.

Szybkie wykluczanie oryginalnych odbiorców „DW” podczas korzystania z opcji „Odpowiedz wszystkim”

1. Na początek uruchom program Outlook.
2. Następnie przejdź do edytora VBA, czytając poprzedni artykuł - „Jak uruchomić kod VBA w swoim Outlooku".
3. Następnie skopiuj następujący kod VBA do projektu „ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when you click "Reply All"
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objRecipient As Outlook.Recipient
    Dim i As Long
 
    'Ask you if to exclude CC recipients
    If MsgBox("Do you want to exclude original CC recipients? " , vbQuestion + vbYesNo) = vbYes Then
       'If select Yes, remove CC recipients
       For i = Response.Recipients.Count To 1 Step -1
           If Response.Recipients(i).Type = olCC Then
              Response.Recipients.Remove (i)
           End If
       Next
    End If
End Sub

4. Następnie uruchom ponownie program Outlook, aby aktywować nowy projekt.
5. Od tego czasu za każdym razem, gdy naciśniesz przycisk „Odpowiedz wszystkim”, pojawi się monit, jak pokazano na poniższym obrazku, z pytaniem, czy chcesz wykluczyć oryginalnych odbiorców DW.
6. Jeśli wybierzesz „Tak”, Outlook automatycznie usunie odbiorców w polu „DW”.

Bądź dobrze przygotowany na uszkodzenia spowodowane przez Outlooka

Jak wszyscy wiemy, nikt nie może w 100% zagwarantować sobie odporności na uszkodzenia spowodowane przez Outlooka. Dlatego wszyscy regularni użytkownicy Outlooka powinni zachować szereg środków ostrożności. Przede wszystkim, jednym z najważniejszych jest tworzenie spójnej i aktualnej kopii zapasowej danych Outlooka. Następnie należy nauczyć się korzystać z narzędzia do naprawy skrzynki odbiorczej. Wreszcie, co nie mniej ważne, zaleca się korzystanie z usług doświadczonego eksperta. Poprawka programu Outlook narzędzie w pobliżu, np DataNumen Outlook Repair.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym odzyskać mdf i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com