6 sposobów na zachowanie oryginalnych załączników wiadomości e-mail podczas odpowiadania w programie Outlook

Wielu użytkowników ma nadzieję, że podczas odpowiadania na wiadomość e-mail w programie Outlook będą zachowywane oryginalne załączniki do wiadomości e-mail. W tym artykule opisano 5 obejść, a także sprytny sposób, w którym VBA jest używany do automatycznej realizacji.

Słyszałem wielu użytkowników narzekających, że Outlook nie ma natywnej funkcji zachowywania oryginalnych załączników podczas odpowiadania na e-mail. Dlatego tutaj udostępnimy Ci 6 metod, z których jedna jest całkiem przydatna, ponieważ wykorzystuje VBA do automatycznego dołączania oryginalnych załączników do wiadomości e-mail w programie Outlook. Teraz przeczytaj, aby uzyskać szczegółowe informacje.

1. Odpowiedz z załączonym oryginalnym e-mailem

Chociaż program Outlook nie zapewnia funkcji przechowywania oryginalnych załączników wiadomości e-mail podczas odpowiadania na wiadomość e-mail, pozwala użytkownikom zachować załączone oryginalne wiadomości e-mail. Dlatego jest to opcjonalne rozwiązanie dla Ciebie. Możesz przejść do sekcji „Plik”> „Opcje”> „Poczta”> „Odpowiedzi i wiadomości przesyłane dalej”, aby zmienić ustawienia odpowiedzi. Aby uzyskać więcej informacji, radzę zapoznać się z moim poprzednim artykułem - „5 kroków, aby odpowiedzieć za pomocą oryginalnych załączników w programie Outlook”. Ale jeśli nadal masz nadzieję zachować tylko oryginalne przywiązania, przejdź dalej, aby nauczyć się innych środków.

2. Ręczne przeciąganie i upuszczanie załączników

1. Na początek kliknij dwukrotnie na taki e-mail źródłowy, aby otworzyć go w osobnym oknie.
2. Następnie kliknij przycisk „Odpowiedz”, co spowoduje wyświetlenie wiadomości e-mail z odpowiedzią.
3. Następnie powinieneś zmniejszyć oba okna wiadomości, aż zobaczysz je na tym samym ekranie.
4. Następnie wybierz wszystkie załączniki w oryginalnej wiadomości e-mail.
5. Na koniec przeciągnij i upuść je w linii „Załączone” w odpowiadającej wiadomości e-mail.

3. Ręczne kopiowanie i wklejanie załączników

1. W pierwszej kolejności po otwarciu źródłowej wiadomości e-mail zaznacz wszystkie załączniki.
2. Następnie kliknij przycisk „Kopiuj” w zakładce „Załączniki”.
3. Następnie kliknij przycisk „Odpowiedz” w zakładce „Wiadomość”, aby otworzyć wiadomość z odpowiedzią.
4. Ostatecznie w odpowiedzi na e-mail kliknij wiersz „Załączony” i naciśnij przycisk „Ctrl + V”, aby wkleić skopiowane wcześniej załączniki.

4. Przekaż wiadomość e-mail i wpisz odbiorcę

1. Najpierw wybierz taki e-mail, a następnie kliknij przycisk „Przekaż” na wstążce.
2. W nowo wyskakującym oknie wiadomości zachowywane są oryginalne załączniki. Teraz musisz wypełnić pole „Do” nadawcy oryginalnej wiadomości e-mail.
3. Opcjonalnie możesz zmienić temat zgodnie ze swoimi potrzebami.

5. Wyślij ponownie tego e-maila i zmień odbiorców

1. Na początek otwórz źródłową wiadomość e-mail.
2. Następnie kliknij przycisk „Działania” w grupie „Przenieś”.
3. Następnie wybierz „Wyślij ponownie tę wiadomość” z rozwijanej listy.
4. Być może otrzymasz alert z informacją, że nie jesteś pierwotnym nadawcą. Po prostu zignoruj ​​to i naciśnij „Tak”.
5. W kolejnym nowym e-mailu powinieneś zmodyfikować pole „Do” na nadawcę oryginalnej wiadomości e-mail.
6. Pamiętaj też, aby zmienić wysyłkę za pomocą konta e-mail na własne konto.

6. Automatyczne dodawanie oryginalnych załączników za pośrednictwem VBA

Wszystkie wymienione powyżej podejścia są, szczerze mówiąc, obejściem. Jeśli masz nadzieję, że Outlook może automatycznie zachowywać oryginalne załączniki podczas odpowiadania, możesz skorzystać z tego sposobu.

1. W głównym oknie Outlooka naciśnij klawisze „Alt + F11”.
2. Następnie w oknie „Microsoft Visual Basic for Applications” skopiuj poniższy kod VBA do projektu „ThisOutlookSession”.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

3. Później podpisz to makro i zmień ustawienia makra programu Outlook, aby zezwolić na podpisane makra.
4. Następnie uruchom ponownie aplikację Outlook, aby aktywować projekt VBA.
5. Od teraz za każdym razem, gdy klikniesz przycisk „Odpowiedz”. Wiadomość e-mail z odpowiedzią zostanie natychmiast wyświetlona z oryginalnymi załącznikami.

Skorzystaj z doskonałego narzędzia naprawczego

Outlook przewyższał innych klientów poczty e-mail ze względu na niezliczone funkcje. Ale nadal jest podatny na korupcję. Dlatego należy zwracać większą uwagę na jego zdrowie. Ogólnie rzecz biorąc, napotykając małe problemy, możesz po prostu wrócić do wbudowanego narzędzia naprawczego. Niemniej jednak, jeśli cierpisz na poważne kłopoty, lepiej powrócić do znacznie sprawniejszego narzędzia, takiego jak DataNumen Outlook Repair. To może naprawić Outlooka plik w mgnieniu oka.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym poprawka sql i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com