Jak wyeksportować strukturę folderów z pliku programu Outlook do programu Excel

Jeśli chcesz szybko wyeksportować strukturę folderów z pliku danych programu Outlook do skoroszytu programu Excel, możesz skorzystać z metody przedstawionej w tym artykule.

Z pewnych powodów, takich jak rejestrowanie bieżących folderów i podfolderów programu Outlook, wielu użytkowników ma nadzieję wyeksportować strukturę folderów pliku programu Outlook do pliku zewnętrznego, takiego jak skoroszyt programu Excel. Poniżej udostępnimy Ci fragment kodu VBA, który pomoże Ci to osiągnąć w mgnieniu oka.

Wyeksportuj strukturę folderów z pliku programu Outlook do programu Excel

1. Na początek uruchom aplikację Outlook.
2. Następnie w głównym oknie Outlooka wciśnij klawisze „Alt + F11”.
3. Następnie przejdziesz do edytora Outlook VBA, w którym należy otworzyć nieużywany moduł.
4. Następnie możesz skopiować następujący kod VBA do tego modułu.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Następnie upewnij się, że program Outlook ma włączone makra.
6. W końcu możesz zrobić zdjęcie:

• W aktualnym oknie makra naciśnij klawisz F5.
• Po zakończeniu działania makra otrzymasz ostrzeżenie „Zakończono”.
• Później możesz udać się do wstępnie zdefiniowanego folderu lokalnego, aby znaleźć nowy plik Excel. Otwórz go i będzie wyglądał jak poniższy zrzut ekranu:

Nigdy nie lekceważ żadnych błędów programu Outlook

Pomimo wielu możliwości Outlook jest tak samo podatny na błędy i korupcję jak inne klienty poczty e-mail. Dlatego powinieneś przywiązywać wagę do wszystkich błędów w programie Outlook. Nie lekceważ ich, proszę. W przeciwnym razie nagromadzenie błędów może ostatecznie doprowadzić do uszkodzenia programu Outlook. W przypadku wystąpienia zawiłych błędów sugeruje się użycie potężnego narzędzia, takiego jak DataNumen Outlook Repair, Który może napraw Outlooka błędy w ciągu kilku sekund.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym odzyskiwanie sql i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com