3 szybkie sposoby usuwania pustych wierszy i kolumn w tabeli słów

W tym poście pokażemy Ci 3 szybkie sposoby usuwania pustych wierszy i kolumn w tabeli programu Word.

Tabele są niezbędne w dokumencie, zwłaszcza w przypadku przechowywania różnych typów danych. Czasami długa tabela może przekraczać jedną stronę i rozciągać się na kilka. Jeśli więc tabela stanie się długa i skomplikowana, możesz podjąć kroki, aby ją uprościć. Na przykład możesz usunąć niepotrzebne puste wiersze i kolumny.

Poniżej przedstawiono 3 metody, których możesz użyć.

Metoda 1: Ręczne usuwanie pustych wierszy i kolumn

1. Najpierw wybierz pusty wiersz lub kolumnę.
2. Następnie kliknij prawym przyciskiem myszy, aby wyświetlić menu kontekstowe. W menu wybierz odpowiednio „Usuń wiersze” lub „Usuń kolumny”.

Niestety, nie możesz zaznaczyć wielu nie następujących po sobie wierszy lub kolumn i usunąć ich razem w ten sposób. W przypadku tego żądania możesz zapoznać się z naszym poprzednim artykułem: 5 szybkich metod grupowego usuwania wielu wierszy lub kolumn w tabeli słów

Metoda 2: Wsadowe usuwanie wszystkich pustych wierszy i kolumn w tabeli

Metoda 1 ma swoje ograniczenia. Zaproponujemy więc sposób zbiorczego usuwania wierszy i kolumn w tabeli za pomocą kodów VBA.

1. Na początek należy umieścić kursor wewnątrz tabeli docelowej.
2. Po drugie, uruchom edytor VBA, naciskając „Alt + F11”.
3. W edytorze najpierw kliknij „Normalny” projekt.
4. Następnie kliknij zakładkę „Wstaw” na pasku menu.
5. Z rozwijanego menu wybierz „Moduł”.
6. Kliknij dwukrotnie moduł, aby go otworzyć i wklej tam następujące kody:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Na koniec kliknij przycisk „Uruchom” na pasku menu lub naciśnij „F5”.

W ciągu kilku sekund usuniesz wszystkie puste wiersze i kolumny z tej tabeli.

Metoda 3: Zbiorcze usuwanie wszystkich pustych wierszy i kolumn we wszystkich tabelach w dokumencie

1. Po pierwsze, powtórz kroki w metodzie 2, aby zainstalować i uruchomić makro.
2. Tylko tym razem zamień to makro na następujące:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Odzyskaj uszkodzony dokument

Obecnie istnieje wiele sposobów na odzyskanie utraconych danych. Na przykład, korzystanie z kopii zapasowych zawsze pozostaje Twoim priorytetem. Jeśli to nie zaspokoi Twojej potrzeby odzyskania najnowszych informacji, możesz spróbować… naprawa doc narzędziem.

Wprowadzenie autora:

Vera Chen jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym xlsx naprawa i pdf oprogramowanie do naprawy. po więcej informacji odwiedź www.datanumen.com