2 szybkie sposoby znajdowania lub usuwania zdań zawierających określony tekst w Twoim słowie

W tym artykule zaproponujemy 2 szybkie sposoby znajdowania lub usuwania zdań zawierających określony tekst w Twoim programie Word.

Wszyscy wiedzą, że funkcja „Znajdź i zamień” w programie Word pozwala łatwo znaleźć wszystkie wystąpienia określonych słów. Wtedy bez problemu je zaznaczymy, zamienimy lub usuniemy. Jak widać, celem jest słowo lub fraza. Dziś jednak z przyjemnością przedstawimy makro, które pozwala znaleźć lub usunąć zdania zawierające określony tekst.

Metoda 1: Znajdź lub usuń zdania zawierające określony tekst

1. Na początek naciśnij „Alt + F11”, aby uruchomić edytor VBA w programie Word.
2. Następnie utwórz nowy moduł, klikając „Normalny”.
3. Następnie kliknij „Wstaw” i wybierz „Moduł”, aby uzyskać nowy.
4. I otwórz moduł podwójnym kliknięciem.
5. Teraz wklej następujące kody:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Następnie kliknij „Uruchom”.
7. Pojawi się pole wprowadzania z prośbą o wprowadzenie tekstu. Po prostu wpisz wspólny tekst, który zawiera wszystkie zdania. Kliknij OK".
8. Następnie zobaczysz zdanie zawierające zaznaczony tekst z okienkiem komunikatu. Kliknij „Tak”, aby usunąć zdanie i „Nie”, aby je zachować.
9. Po potwierdzeniu, kolejne zdanie z wybranym tekstem jest zaznaczone. Znajduje się tam również pole potwierdzenia. Makro przeprowadza Cię przez cały dokument, znajdując zdania docelowe i pytając za każdym razem o potwierdzenie.

Metoda 2: Znajdź lub usuń zdania zawierające dowolny tekst na liście

Za pomocą makra w metodzie 1 możesz wyszukiwać tylko jedno słowo lub frazę na raz. Oczywiście możesz wielokrotnie uruchamiać makro, aby wyszukać wiele wystąpień słów lub fraz. Aby sprostać potrzebie wielokrotnego wyszukiwania, udostępnimy Ci kolejne makro.

1. Najpierw umieść wszystkie teksty docelowe w nowym dokumencie. Upewnij się, że każdy fragment tekstu zajmuje jeden akapit i nie ma spacji na końcu. Zamknij i zapisz dokument.
2. Następnie zainstaluj i uruchom makro z dokładnymi krokami w metodzie 1.
3. Następnie zamień makro na to:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Teraz otworzy się okno „Przeglądaj”. Wybierz właśnie zapisany dokument i kliknij „Otwórz”.
5. Poniższa procedura jest taka sama, jak w metodzie 1.

Podejście do postępowania w przypadku uszkodzonych dokumentów

Utrata cennych danych jest absolutnie katastrofalna. Może nawet narazić Twój biznes na niebezpieczeństwo. Aby uniknąć takiej frustracji, potrzebujesz pomocy Poprawka słów narzędzie tak szybko, jak to możliwe. Takie narzędzie pomoże Ci wygrać walkę z uszkodzeniem dokumentów.

Wprowadzenie autora:

Vera Chen jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym naprawić program Excel i pdf oprogramowanie do naprawy. po więcej informacji odwiedź www.datanumen.com