So finden Sie schnell Absätze mit einem Satz in Ihrem Word-Dokument

In diesem Beitrag möchten wir Ihnen den schnellen Weg aufzeigen, wie Sie mithilfe von VBA alle Ein-Satz-Absätze in Ihrem Word-Dokument finden können.

Ab und zu können einige Dokumente sehr spezielle Anforderungen an ihre Formatierung und Struktur stellen. Beispielsweise dürfen Sie möglicherweise keine Absätze mit nur einem Satz haben. Diese Absätze sind nicht schwer zu erkennen, aber es braucht Zeit, insbesondere ist es ein langes Dokument.

Heute bieten wir Ihnen die schnelle Möglichkeit, alle Absätze mit einem Satz in Ihrem Dokument anzugeben.

Alle Absätze mit einem Satz in einem Dokument finden

1. Erstens zählt Word einen Punkt als Satz. Also, wenn es Wörter wie "Mr." gibt oder "Frau", Word betrachtet es als Satz. Um eine solche Ablenkung auszuschließen, müssen Sie "Mr." ersetzen. mit "Mr". Und wenn Sie den Absatz eines einzelnen Satzes gefunden haben, können Sie ihn wieder ändern. Um Wörter zu ersetzen, können Sie auf diesen Link verweisen: So finden und ersetzen Sie mehrere Elemente in Ihrem Word-Dokument
2. Zweitens drücken Sie "Alt + F11", um den VBA-Editor auszulösen.
3. Klicken Sie dann auf "Normal".
4. Klicken Sie in der Menüleiste auf die Registerkarte „Einfügen“ und wählen Sie im Dropdown-Menü die Option „Modul“.
5. Doppelklicken Sie anschließend auf das Modul, um es zu öffnen.
6. Fügen Sie folgende Codes in das Modul ein:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Last but not least klicken Sie auf die Schaltfläche "Ausführen" oder drücken Sie "F5".

Sie erhalten ein solches Meldungsfeld, in dem Sie darüber informiert werden, dass die Arbeit erledigt ist.

Finden Sie alle Absätze mit einem Satz in mehreren Dokumenten

1. Zunächst müssen Sie alle Zieldokumente in einem Ordner ablegen.
2. Installieren Sie dann das folgende Makro und führen Sie es aus:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Wählen Sie im geöffneten Fenster "Durchsuchen" den Ordner aus, in dem Sie Dokumente aufbewahren, und klicken Sie auf "OK".

Das Makro hebt dann alle Absätze mit einem Satz hervor und lässt Dokumente offen. Wenn ein Dokument keinen Absatz mit einem Satz enthält, wird es geschlossen. Außerdem gibt es ein Meldungsfeld, in dem die Anzahl der Absätze mit einem Satz in jedem Dokument angegeben ist.

Umgang mit Datenverlust Vorfällen

Benutzerfehler und plötzlicher Stromausfall können zum Tod von Word führen. Ein zusammengebrochenes Wort kann zwar nicht nur die tägliche Arbeit beeinträchtigen, sondern auch dazu führen doc SchadenDas ist bei Weitem nicht der ärgerlichste Aspekt eines Datenverlusts. Am besten ist es, ein Reparaturprogramm zu verwenden, um die Daten sofort wiederherzustellen.

Einführung des Autors:

Vera Chen ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich Excel wiederherstellen und pdf Reparatur von Softwareprodukten. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX