So fügen Sie schnell bestimmte Seiten eines Word-Dokuments an eine Outlook-E-Mail an

MS Word verfügt über eine Direktfunktion, mit der Benutzer das aktuelle Word-Dokument als E-Mail-Anhang senden können. Aber manchmal hoffen Sie möglicherweise nur, bestimmte Seiten eines Word-Dokuments an eine Outlook-E-Mail anzuhängen. In diesem Artikel erfahren Sie nun eine Methode.

Um ein ganzes Word-Dokument als E-Mail-Anhang in der MS Word-Anwendung zu versenden, gehen Sie einfach zum Menü „Datei“ und wechseln zur Registerkarte „Speichern und Senden“, unter der Sie die Schaltfläche „Als Anhang senden“ finden. Dennoch kann es vorkommen, dass Sie nur bestimmte Seiten des Dokuments senden möchten. In dieser Situation können Sie die im Folgenden vorgestellte Methode verwenden, um dies zu erreichen.

Hängen Sie bestimmte Seiten eines Word-Dokuments an eine E-Mail an

1. Zunächst sollten Sie das Word-Quelldokument öffnen, dessen spezifische Seiten Sie per E-Mail versenden möchten.
2. Nachdem Sie das MS Word-Fenster geöffnet haben, müssen Sie die Tasten „Alt + F11“ drücken.
3. Als nächstes erhalten Sie Zugriff auf den VBA-Editor in MS Word.
4. Anschließend müssen Sie die „Microsoft Outlook-Objektbibliothek“ aktivieren. Dies erreichen Sie über „Extras“ > „Verweise“.
5. Anschließend sollten Sie den folgenden VBA-Code in ein Modul kopieren, das nicht verwendet wird.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Schließlich können Sie dieses Makro ausführen. Drücken Sie einfach die Taste F5 oder tippen Sie auf das Symbol „Ausführen“ in der Symbolleiste.
7. Nachdem das Makro abgeschlossen ist, wird eine neue Outlook-E-Mail angezeigt, die mit einem Auszug des Word-Quelldokuments angehängt ist, wie im folgenden Screenshot:

Extrahieren Sie maximale Daten aus einer beschädigten Outlook-Datei

Wenn Sie Outlook jahrzehntelang verwendet haben, waren Sie möglicherweise mit verschiedenen Outlook-Problemen konfrontiert, darunter Popup-Fehlermeldungen, plötzliche Abstürze und schwerwiegende Dateischäden. Aufgrund der Tatsache, dass die scanpstDa das integrierte Reparaturtool nur kleine Probleme lösen kann, halten Sie beispielsweise besser ein externes, leistungsstarkes Reparaturtool bereit DataNumen Outlook Repair. Es ist in der Lage, maximale Daten aus der beschädigten Outlook-Datendatei abzurufen.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich SQL Fix und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX