So erhalten Sie eine Benachrichtigung, wenn Sie die Antwort einer bestimmten E-Mail nicht innerhalb der erwarteten Zeit erhalten

In diesem Artikel erfahren Sie einen schnellen Trick mit VBA, mit dem Outlook Sie automatisch auffordert, eine Benachrichtigungs-E-Mail zu senden, wenn Sie innerhalb einer bestimmten Zeit keine Antwort auf eine bestimmte E-Mail erhalten haben.

Manchmal werden Sie sich bei den lebenswichtigen E-Mails auf jeden Fall auf die Antworten freuen. Mit anderen Worten, Sie müssen hoffen, dass der Empfänger Ihnen so schnell wie möglich antworten kann. Andernfalls senden Sie dem Empfänger erneut eine Follow-up-Benachrichtigungs-E-Mail, solange Sie die Antwort nicht innerhalb der erwarteten Zeit erhalten haben. Als Reaktion auf diese Anforderung stellen wir hier eine Methode vor, mit der Outlook mithilfe von VBA automatisch gewarnt und in einem solchen Fall aufgefordert wird. Lesen Sie weiter, um die ausführlichen Schritte und Codes zu erhalten.

Erhalten Sie eine Benachrichtigung, wenn Sie die Antwort einer bestimmten E-Mail nicht innerhalb der erwarteten Zeit erhalten

1. Gleich zu Beginn start Ihren Ausblick.
2. Dann müssen Sie eine bestimmte Erinnerungszeit für die bestimmte E-Mail festlegen.

• Klicken Sie zunächst mit der rechten Maustaste auf die jeweilige E-Mail.
• Wählen Sie dann "Follow Up"> "Add Reminder".
• Im Dialogfeld können Sie die Erinnerungszeit auf die bestimmte Zeit einstellen, innerhalb der Sie die Antwort erhalten möchten.

3. Drücken Sie danach die Tasten „Alt + F11“, um auf den Outlook VBA-Editor zuzugreifen.
4. Öffnen Sie als Nächstes im neuen Fenster das Projekt "ThisOutlookSession" und kopieren Sie die folgenden Codes hinein.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Unterschreiben Sie anschließend diesen Code.
6. Ändern Sie später die Outlook-Makroeinstellung, um die digital signierten Makros zuzulassen.
7. Schließlich restart Outlook, um das neue Makro zu aktivieren. Von nun an funktioniert Outlook wie folgt:

• Wenn Sie die Antwort der jeweiligen E-Mail erhalten haben, bevor die Erinnerung angezeigt wird, löscht Outlook das Flag automatisch und deaktiviert die Erinnerung.
• Wenn Sie die Antwort beim Auslösen der Erinnerung nicht erhalten haben, werden Sie von Outlook gefragt, ob Sie eine Follow-up-Benachrichtigungs-E-Mail senden möchten. Wenn Sie "Ja" auswählen, wird die E-Mail gesendet. Wenn Sie "Nein" auswählen, wird die Eingabeaufforderung sofort ausgeblendet.

Beheben Sie lästige Outlook-Probleme

Da Outlook fehleranfällig ist, um dies zu verhindern Outlook-KorruptionSie sollten sich nicht nur auf das Posteingangstool Scanpst.exe verlassen. Sie sollten ein anderes leistungsstarkes und seriöses Reparaturwerkzeug vorbereiten, z DataNumen Outlook RepairDies kann die lästigen Probleme beseitigen, die Scanpst.exe nicht lösen kann.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich SQL-Korruption und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX