2 Methoden zum Exportieren aller Mitglieder einer Outlook-Kontaktgruppe nach Excel

Manchmal möchten Sie möglicherweise die Mitglieder in eine bestimmte Outlook-Kontaktgruppe exportieren. In diesem Artikel erhalten Sie zwei Möglichkeiten, um die Gruppenmitglieder nach Excel zu extrahieren.

Outlook bietet eine native Funktion, mit der Sie alle Kontakte eines bestimmten Kontaktordners exportieren können. Sie können jedoch keine Kontaktgruppen exportieren und die Mitglieder in den Kontaktgruppen nicht extrahieren. Wenn Sie die Mitglieder einer ausgewählten Kontaktgruppe extrahieren möchten, müssen Sie daher weitere Anstrengungen unternehmen. Hier sind zwei Tipps, auf die Sie sich beziehen können.

Methode 1: Extrahieren Sie die Gruppenmitglieder über Speichern unter

1. Starten Sie gleich zu Beginn Outlook.
2. Suchen Sie dann die Kontaktgruppe und wählen Sie sie aus, deren Mitglieder Sie extrahieren müssen.
3. Als nächstes sollten Sie zum Menü "Datei" gehen und auf "Speichern unter" klicken.
4. Wählen Sie anschließend im Popup-Dialogfeld "Speichern unter" einen zu speichernden Zielordner aus und wählen Sie "Nur Text" aus der Dropdown-Liste "Dateityp".
5. Und dann klicken Sie auf "Speichern".
6. Öffnen Sie danach Excel und erstellen Sie eine neue Excel-Datei.
7. Später sollten Sie zu "Datei" wechseln und auf "Öffnen" klicken.
8. Im nachfolgenden Dialogfeld "Öffnen" sollten Sie zuerst auf den Ordner zugreifen, in dem Sie die Kontaktgruppe gerade gespeichert haben.
9. Klicken Sie dann auf das zweite Feld in der Zeile "Dateiname" und wählen Sie "Alle Dateien" aus der Dropdown-Liste aus.
10. Stellen Sie danach die Textdatei für die Kontaktgruppe auf und klicken Sie auf "Öffnen".
11. Stellen Sie im Popup-Dialogfeld "Textimport-Assistent" sicher, dass "Begrenzt" ausgewählt ist, und klicken Sie auf "Fertig stellen".
12. Schließlich erhalten Sie die Mitglieder, wie der folgende Screenshot:

Methode 2: Extrahieren Sie die Gruppenmitglieder über Outlook VBA

1. Drücken Sie zunächst in Outlook die Tasten „Alt + F11“.
2. Öffnen Sie dann ein neues Modul im VBA-Editorfenster.
3. Kopieren Sie anschließend die folgenden VBA-Codes hinein.

Sub ExtractContactGroupMembersToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objMember As Outlook.recipient
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strPath As String
    Dim strFilename As String
 
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objContactGroup = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objContactGroup = Application.ActiveInspector.CurrentItem
    End Select
 
    If TypeOf objContactGroup Is DistListItem Then
       'Create a new Excel workbook
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkBook = objExcelApp.Workbooks.Add
       Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
       'Set the two column headers
       objExcelWorkSheet.Cells(1, 1) = "Contact Name"
       objExcelWorkSheet.Cells(1, 2) = "Email Address"

       nRow = 2
 
       'Extract the contact group members' names and email addresses
       For i = 1 To objContactGroup.MemberCount
           Set objMember = objContactGroup.GetMember(i)
           objExcelWorkSheet.Cells(nRow, 1) = objMember.Name
           objExcelWorkSheet.Cells(nRow, 2) = objMember.Address
           nRow = nRow + 1
       Next
 
       'AutoFit the columns in the new Excel worksheet
       objExcelWorkSheet.Columns("A:B").AutoFit
 
       'Change the strPath to your actual case
       strPath = "C:\Contact Groups\"
       strFilename = strPath & objContactGroup.DLName & ".xlsx"
 
       'Save the Excel workbook
       objExcelWorkBook.Close True, strFilename
 
       'Notify you of the export complete
       MsgBox ("Export Complete!")
    End If
End Sub

4. Danach können Sie das Makro wie gewohnt zur Quick Access Toolbar (QAT) hinzufügen.
5. Später können Sie eine Kontaktgruppe auswählen und in QAT auf die Makro-Schaltfläche klicken.
6. Nach dem Export erhalten Sie die Meldung "Export abgeschlossen!"
7. Schließlich finden Sie die Excel-Datei in dem Ordner, der in VBA-Codes vorgegeben ist. Öffnen Sie es, Sie können die Gruppenmitglieder sehen, wie das Bild unten:

Holen Sie sich Ihre vorherigen PST-Daten zurück

Da Outlook anfällig für Abstürze ist, können Ihre PST-Daten ohne Vorzeichen beschädigt werden. Daher sollten Sie Ihre PST-Dateien regelmäßig sichern. Außerdem sollten Sie besser ein leistungsfähiges Werkzeug vorbereiten, wie z DataNumen Outlook Repair, Denen Outlook reparieren Daten rechtzeitig.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich Fix SQL und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX