So fügen Sie Notizen effektiv zu Outlook-E-Mails über VBA und UserForm hinzu

Manchmal können Sie hoffen, Ihre E-Mails in Outlook zu bearbeiten oder Notizen hinzuzufügen. In diesem Artikel erfahren Sie, wie Sie diese Funktion effektiv erreichen können.

Von "4 Einfache Methoden zum Einfügen einer Notiz in Ihre Outlook-Nachrichten„Sie können lernen, Notizen über native Outlook-Funktionen in E-Mails einzufügen, z. B. benutzerdefinierte Flags verwenden, Notizen in Betreff oder Text eingeben oder vorhandene Notizelemente an diese E-Mail anhängen. Alle sind jedoch nur Problemumgehungen. Hier bringen wir Ihnen eine viel effektivere Methode bei. Darüber können Sie E-Mails Notizen hinzufügen und vorhandene Notizen nach Belieben bearbeiten oder löschen.

Hinzufügen von Notizen zu Outlook-E-Mails

1. Greifen Sie zunächst auf den VBA-Editor zu, indem Sie in Outlook auf „Alt + F11“ klicken.
2. Klicken Sie dann auf "Einfügen"> "UserForm".
3. Erstellen Sie als Nächstes in der neuen UserForm ein Textfeld wie das folgende Bild.
4. Ändern Sie dann den "Namen" des Textfelds wie im Screenshot in "txtNotes".
5. Erstellen Sie anschließend zwei Befehlsschaltflächen im Formular.
6. Wählen Sie dann "CommandButton 1". Ändern Sie den "Namen" in "btnOK" und die "Beschriftung" in "OK".
7. Ändern Sie anschließend den "Namen" von "CommandVutton 2" in "btnCancel" und die "Beschriftung" in "Cancel".
8. Wählen Sie als Nächstes die gesamte UserForm aus und ändern Sie ihren "Namen" in "frmAddNote" und "Beschriftung" in "Geben Sie Ihre Notiz ein".
9. Klicken Sie anschließend mit der rechten Maustaste auf "fromAddNote" und wählen Sie "Code anzeigen".
10. Kopieren Sie im neuen Bildschirm den folgenden Code hinein.

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objNote = Application.CreateItem(olNoteItem)
 
    objNote.Body = strNote
    objNote.Save
    objMail.Attachments.Add objNote
    objMail.Save
    objNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

11. Fügen Sie später den folgenden VBA-Code in ein nicht verwendetes Modul ein.

Sub AddNote()
    frmAddNote.Show
End Sub

12. Gehen Sie schließlich zu "Datei"> "Optionen"> "Multifunktionsleiste anpassen", um dieses Makro zur Multifunktionsleiste hinzuzufügen.
13. Jetzt können Sie es versuchen. Wählen Sie eine E-Mail aus und klicken Sie im Menüband auf die neue Schaltfläche "Notiz hinzufügen".
14. Im Popup-Dialogfeld können Sie Ihre Notiz eingeben und auf „OK“ klicken.
15. Sofort wird der ausgewählten E-Mail eine neue Notiz hinzugefügt.

Bearbeiten oder Löschen vorhandener Notizen für Outlook-E-Mails

Manchmal möchten Sie möglicherweise vorhandene Notizen in einer E-Mail bearbeiten oder löschen. Sie können die folgenden Schritte ausführen.

1. Erstellen Sie zunächst ein anderes Benutzerformular, benennen Sie es als "frmEditNote" und ändern Sie die Beschriftung in "Notiz bearbeiten".
2. Fügen Sie dann ein neues Textfeld in das Formular ein und ändern Sie dessen "Name" in "txtNotes".
3. Fügen Sie als Nächstes zwei Befehlsschaltflächen hinzu - "OK" und "Abbrechen".
4. Klicken Sie danach mit der rechten Maustaste auf "frmEditNote" und wählen Sie "Code anzeigen".
5. Geben Sie auf der neuen Codepage von "frmEditNote" den folgenden Code ein.

Private Sub UserForm_Initialize()
    Dim objAttachNote As Outlook.Attachment
    Dim objTempNote As Outlook.NoteItem

    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    Set objMail = objAttachNote.Parent
 
    If Right(objAttachNote.FileName, 3) = "msg" Then
       strTempFolder = Environ("Temp")
       strFilePath = strTempFolder & "\" & objAttachNote.FileName
       objAttachNote.SaveAsFile strFilePath
    End If
 
    Set objTempNote = Session.OpenSharedItem(strFilePath)
    txtNotes.Text = objTempNote.Body

    objTempNote.Close olDiscard
End Sub

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objAttachNote As Outlook.Attachment
    Dim objNewNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objNewNote = Application.CreateItem(olNoteItem)
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    objAttachNote.Delete

    objNewNote.Body = strNote
    objNewNote.Save
    objMail.Attachments.Add objNewNote
    objMail.Save
    objNewNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

6. Öffnen Sie danach ein Modul und kopieren Sie den VBA-Code hinein.

Sub EditNote()
    frmEditNote.Show
End Sub

Sub DeleteNotes()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim objMail As Outlook.MailItem
 
    Set objSelectedAttachments = Application.ActiveExplorer.AttachmentSelection
 
    For Each objAttachment In objSelectedAttachments
        If Right(objAttachment.FileName, 3) = "msg" Then
           objAttachment.Delete
        End If
    Next
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    objMail.Save
End Sub

7. Schließlich können Sie dem Menüband die Makros "EditNote" und "DeleteNotes" hinzufügen.
8. Nachdem Sie auf „OK“ geklickt und zum Hauptfenster zurückgekehrt sind, können Sie versuchen, eine Notiz zu bearbeiten.

• Wählen Sie eine Notiz aus und klicken Sie auf die Schaltfläche „Notiz bearbeiten“.
• Anschließend wird ein neues Dialogfeld angezeigt, in dem Sie die ausgewählte Notiz bearbeiten können.
• Klicken Sie nach der Bearbeitung auf "OK". Der Hinweis wird aktualisiert.

9. Sie können auch versuchen, Notizen zu löschen.

• Wählen Sie die Notiz aus, die Sie löschen möchten.
• Klicken Sie im Menüband auf die Schaltfläche „Notizen löschen“.
• Dieser Hinweis wird sofort gelöscht.

Verhindern Sie, dass Outlook Daten verliert

Suchen Sie nach einer mächtigen Lösung, um den Verlust von Outlook-Daten zu blockieren? Um ehrlich zu sein, können Sie PST-Datenverluste problemlos vermeiden, solange Sie regelmäßig Outlook-Datensicherungen durchführen. Selbst wenn PST beschädigt wird, können Sie dies dennoch problemlos tun PST wiederherstellen Daten aus der gesicherten PST-Datei wie ein Kinderspiel.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich SQL wiederherstellen und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX