2 Möglichkeiten zum schnellen Zusammenführen mehrerer Word-Dokumente zu einem über VBA

In diesem Artikel möchten wir Ihnen zwei Möglichkeiten vorstellen, wie Sie mehrere Word-Dokumente über VBA schnell zu einem zusammenführen können.

In Word gibt es die standardmäßig integrierte Funktion, mit der Benutzer mehrere Dokumente zu einem kombinieren oder zusammenführen können. Details werden in diesem Artikel erklärt: Kombinieren und Zusammenführen mehrerer Word-Dokumente zu einem

Mit dieser Methode müssen Sie ein paar Klicks machen und der Inhalt des nächsten Dokuments kommt immer direkt nach dem des vorherigen Dokuments. Deshalb möchten wir Ihnen schnellere Möglichkeiten dazu bieten.

Methode 1: Ausgewählte Dokumente zu einem zusammenführen

1. Als Erstes erstellen Sie ein neues, leeres Dokument.
2. Lösen Sie den VBA-Editor in Word aus, indem Sie „Alt + F11“ drücken.
3. Klicken Sie anschließend auf "Normal".
4. Klicken Sie dann auf "Einfügen".
5. Und wählen Sie "Modul".
6. Doppelklicken Sie auf neues Modul, um den Bearbeitungsbereich zu öffnen.
7. Fügen Sie dort das folgende Makro ein:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Klicken Sie anschließend auf "Ausführen" oder drücken Sie "F5".
9. Wählen Sie nun im Fenster "Durchsuchen" mehrere Dateien aus, indem Sie "Strg" drücken und auf "OK" klicken.
10. Anschließend werden alle Inhalte der ausgewählten Dateien in dem neuen Dokument zusammengefügt, wobei die Texte jedes Dokuments auf einer neuen Seite beginnen.

Hinweis:

Wie bereits erwähnt, werden mit diesem Makro die Texte jedes Dokuments auf einer neuen Seite angezeigt. Wenn sie jedoch nacheinander angezeigt werden müssen, können Sie einige Codezeilen im Makro ändern. Suchen Sie einfach die Zeile "If nEachSelectedFile <nTotalFiles Then", löschen Sie sie und die nächsten sechs Zeilen.

Methode 2: Alle Dokumente in einem Ordner zu einem zusammenführen

Wenn Sie einen Ordner mit zu kombinierenden Dateien haben, funktioniert dieses Makro einwandfrei.

1. Installieren und starten Sie zunächst das Makro wie in Methode 1 beschrieben.
2. Ersetzen Sie dann das Makro durch dieses:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Führen Sie das Makro aus, indem Sie auf "Ausführen" klicken.
4. Als nächstes wird das Fenster "Durchsuchen" geöffnet. Wählen Sie den Ordner aus, in dem Sie alle Dokumente speichern. Und klicken Sie auf "OK".

Ebenso beginnt der Text jedes Dokuments auf einer neuen Seite. Um die Texte zusammenhängend nacheinander anzuordnen, suchen und löschen Sie die Codezeile „.InsertBreak Type:=wdPageBreak“.

Schützen Sie Ihr Word-Dokument ordnungsgemäß

Eine der besten Möglichkeiten, Ihre Word-Dokumente zu schützen, besteht darin, sie regelmäßig zu sichern. Mit Backups in der Hand müssen Sie niemals den Verlust von Daten befürchten. Außerdem ist es auch ratsam, ein Werkzeug zu bekommen docx reparieren wenn einer von ihnen beschädigt werden soll.

Einführung des Autors:

Vera Chen ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich beschädigtes Excel und pdf Reparatur von Softwareprodukten. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX