2 Schnelle Möglichkeiten zum Exportieren der Liste aller markierten Outlook-E-Mails nach Excel

Wenn Sie die Liste aller gekennzeichneten E-Mails aus Ihrem Outlook-Postfach nach Excel exportieren möchten, können Sie eine der beiden in diesem Artikel beschriebenen Methoden verwenden.

Um beispielsweise alle gekennzeichneten E-Mails schneller zu bearbeiten oder sie an andere weiterzugeben, können Sie sie in ein Excel-Arbeitsblatt exportieren. Hier werden wir zwei Ansätze vorstellen, um dies zu realisieren. Ersteres verwendet die Standardfunktion "Importieren und Exportieren", nachdem markierte E-Mails gefunden wurden. Um ehrlich zu sein, ist es ein bisschen langweilig. In letzterem Fall werden wir Ihnen daher eine bequemere Methode zur Anwendung von VBA beibringen.

Methode 1: Alle gefundenen gekennzeichneten E-Mails manuell exportieren

1. Klicken Sie zunächst in das Suchfeld über der Mailingliste.
2. Klicken Sie dann in der Gruppe "Bereich" auf der Registerkarte "Suchen" auf "Alle E-Mail-Artikel".
3. Klicken Sie anschließend in der Gruppe "Definieren" auf die Schaltfläche "Markiert".
4. Nachdem alle markierten E-Mails in der Liste angezeigt wurden, wählen Sie eine E-Mail aus und drücken Sie „Strg + A“, um alle auszuwählen.
5. Drücken Sie dann die Tastenkombinationen „Strg + Umschalt + V“.
6. Erstellen Sie im neuen Dialogfeld einen neuen Ordner unter der Outlook-Datei.
7. Wählen Sie später den neu erstellten Ordner aus und klicken Sie auf "OK". Dadurch werden alle gefundenen markierten E-Mails in den neuen Ordner verschoben.
8. Klicken Sie anschließend auf "Datei"> "Öffnen"> "Importieren".
9. Wählen Sie im Popup-Dialogfeld "In eine Datei exportieren"> "Weiter"> "Microsoft Excel 97-2003"> "Weiter".
10. Wählen Sie im neuen Bildschirm den richtigen Ordner aus und klicken Sie auf "Weiter".
11. Folgen Sie anschließend den Assistenten, um "Exportieren" abzuschließen.
12. Sie erhalten eine neue Excel-Datei, die im folgenden Screenshot dargestellt ist.

Methode 2: Exportieren Sie die Liste aller gekennzeichneten E-Mails über VBA

1. Drücken Sie in Outlook „Alt + F11“, um den VBA-Editor auszulösen.
2. Aktivieren Sie dann "MS Excel Object" gemäß "Wie man in VBA einen Objektbibliotheksverweis hinzufügt".
3. Kopieren Sie anschließend den folgenden VBA-Code in ein Modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Zuletzt setzen Sie den Cursor in die Unterroutine „ExportAllFlaggedEmailsToExcel“ und drücken Sie die Taste „F5“.
5. Wählen Sie dann im neuen Dialogfeld eine Outlook-Datei aus.
6. Wenn Sie die Aufforderung "Abgeschlossen" erhalten, erhalten Sie auch eine neue Excel-Datei, wie im Bild unten dargestellt.

Schützen Sie Ihren Ausblick vor Korruption

Outlook ist fehleranfällig und kann leicht beschädigt werden, weshalb es sehr aufwendig ist, unsere Outlook-Daten zu schützen. Der effektivste und praktischste Weg ist zweifellos die regelmäßige Datensicherung. Zusätzlich ist es notwendig, ein leistungsstarkes und zuverlässiges Outlook-Reparaturtool zu verwenden, wie zum Beispiel … DataNumen Outlook Repair. Es wird nützlich sein, wenn Reparaturwerkzeug für den Posteingang macht keine Wirkung.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich fixieren SQL Server und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX