2 Methoden zum schnellen Senden ausgewählter Zellen in einem Excel-Arbeitsblatt als Outlook-E-Mail

Manchmal möchten Sie die ausgewählten Zellen in einem Excel-Arbeitsblatt schnell in eine Outlook-E-Mail einfügen und diese E-Mail senden. Dieser Artikel befasst sich mit diesem Wunsch, Ihnen 2 Methoden anzubieten.

Mein vorheriger Artikel “2 Schnelle Methoden zum Senden eines Excel-Arbeitsblatts als Outlook-E-Mail”Hat Ihnen beigebracht, wie Sie ein ganzes Excel-Arbeitsblatt als E-Mail senden. Manchmal möchten Sie jedoch nur die ausgewählten Zellen in einem Arbeitsblatt als E-Mail senden. Als Antwort auf diese Anforderung werden wir Ihnen hier zwei Methoden vorstellen. Sie können entweder nach Ihren Wünschen wählen.

Methode 1: Ausgewählte Zellen manuell per E-Mail kopieren

1. Öffnen Sie zunächst die Excel-Quelldatei und rufen Sie das richtige Excel-Arbeitsblatt auf.
2. Wählen Sie dann die Zellen aus, die Sie als Outlook-E-Mail senden möchten.
3. Drücken Sie anschließend die Tastenkombinationen „Strg + C“, um die ausgewählten Zellen zu kopieren.
4. Starten Sie danach Ihre Outlook-Anwendung.
5. Klicken Sie anschließend im Menüband "Startseite" auf die Schaltfläche "Neue E-Mail", um eine neue Outlook-E-Mail zu erstellen.
6. Klicken Sie später im neuen Nachrichtenfenster in den Abschnitt Nachrichtentext.
7. Drücken Sie dann die Tasten „Strg + V“, um die zuvor kopierten ausgewählten Excel-Zellen einzufügen.
8. Zuletzt können Sie die E-Mail wie gewohnt verfassen und auf die Schaltfläche „Senden“ klicken, um sie zu versenden.

Methode 2: Ausgewählte Zellen als E-Mail über VBA senden

1. Öffnen Sie gleich zu Beginn die Excel-Quellarbeitsmappe.
2. Drücken Sie dann die Tasten „Alt + F11“, um auf den Excel VBA-Editor zuzugreifen.
3. Klicken Sie im neuen Fenster auf "Einfügen"> "Modul", um ein neues Modul einzufügen.
4. Aktivieren Sie anschließend die Microsoft Outlook-Objektbibliothek. Klicken Sie auf „Extras“ > „Verweise“. Suchen Sie im Popup-Dialogfeld die „Microsoft Outlook-Objektbibliothek“ und aktivieren Sie das Kontrollkästchen.
5. Kopieren Sie anschließend den folgenden VBA-Code in dieses Modul.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Schließlich können Sie es versuchen.

• Wählen Sie zunächst wie gewohnt die spezifischen Zellen aus.
• Kehren Sie dann zum neuen Makro zurück und drücken Sie die Taste F5, um es auszulösen.
• Sofort wird eine neue Outlook-E-Mail angezeigt, in der Sie sehen können, dass die ausgewählten Zellen in den E-Mail-Text eingefügt wurden, wie im folgenden Screenshot dargestellt:

Die PST-Datei ist genauso anfällig wie die Excel-Datei

Wie wir wissen, sind Excel- und Word-Dateien anfällig für Beschädigungen. Dasselbe gilt für PST-Dateien, die alle Elemente Ihres Outlook-Postfachs enthalten. Daher ist es eine anspruchsvolle Aufgabe, Ihre PST-Daten zu sichern. Eine der effektivsten Maßnahmen ist die regelmäßige Datensicherung. Um im Notfall schnell auf Ihre Daten zugreifen zu können, sollten Sie außerdem ein zuverlässiges Tool wie beispielsweise [Name des Tools einfügen] bereithalten. DataNumen Outlook Repair, das kann Outlook wiederherstellen Daten ohne ins Schwitzen zu geraten.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich mdf reparieren und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX