Så här fäster du snabbt de specifika bilderna på a PowerPoint Presentation till din Outlook-e-post

Om du vill extrahera de specifika bilderna på a PowerPoint presentation till en separat ny presentation och bifoga den till ett e-postmeddelande i Outlook, kan du använda det sätt som delas i den här artikeln.

Istället för att fästa en hel PowerPoint presentation till ett e-postmeddelande, om du vill bifoga de specifika bilderna i presentationen, i allmänhet måste du först kopiera de specifika bilderna till en ny presentation. Det är för besvärligt. Därför visar vi dig här en metod som kan förverkliga den på en gång.

Bifoga de specifika bilderna på a PowerPoint Presentation till ett e-postmeddelande

1. Först och främst, öppna specifikationen PowerPoint presentation.
2. Då, i PowerPoint applikationsfönster, tryck på “Alt + F11” för att komma åt VBA-redigeraren.
3. Skapa sedan en ny modul i det nya fönstret genom att trycka på "Infoga"> "Modul".
4. Kopiera sedan och klistra in följande VBA-kod i den här modulen.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Därefter kan du stänga det aktuella fönstret.
6. Senare går du till "Arkiv"> "Alternativ"> "Snabbåtkomstverktygsfält" för att lägga till det nya makrot i Snabbåtkomstverktygsfältet.
7. Slutligen kan du prova detta makro.

• Till att börja med, välj de specifika bilder som du vill extrahera.
• Klicka sedan på makroknappen i verktygsfältet Snabbåtkomst.
• Omedelbart visas ett e-postmeddelande i Outlook där det finns en PowerPoint presentation som extraheras från källpresentationen.

Använd ett effektivt återställningsverktyg

Som vi alla vet är Outlook utrustat med ett inbyggt reparationsverktyg - Scanpst. Ändå kan det helt enkelt klara av små problem i Outlook. Om det du står inför är allvarlig skada, kommer det inte att påverka. Vid den tiden har du inget annat val än att återgå till ett annat kraftfullt och pålitligt reparationsverktyg, som DataNumen Outlook Repair. Med den kommer du att kunna rädda din skadade Outlook-fil.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive skadad mdf och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com