Jak szybko znaleźć jednozdaniowe akapity w dokumencie programu Word

W tym poście chcemy pokazać Ci, jak szybko znaleźć wszystkie akapity składające się z jednego zdania w dokumencie Word za pomocą języka VBA.

Czasami niektóre dokumenty mogą mieć bardzo specyficzne wymagania dotyczące formatowania i struktury. Na przykład możesz nie mieć prawa do paragrafów zawierających tylko jedno zdanie. Te akapity nie są trudne do rozpoznania, ale wymaga to czasu, zwłaszcza że jest to długi dokument.

Dzisiaj zaoferujemy Ci szybki sposób określenia wszystkich jednozdaniowych akapitów w dokumencie.

Znajdź wszystkie jednozdaniowe akapity w jednym dokumencie

1. Po pierwsze, Word liczy kropkę jako zdanie. Jeśli więc są takie słowa, jak „pan” lub „pani”, Word uważa to za zdanie. Aby wykluczyć takie rozproszenie, musisz zamienić „Mr.” z „Pan”. A kiedy skończysz znaleźć akapit pojedynczego zdania, możesz je zmienić z powrotem. Aby zamienić słowa, możesz skorzystać z tego linku: Jak znaleźć i zamienić wiele elementów w dokumencie programu Word
2. Po drugie, naciśnij „Alt + F11”, aby uruchomić edytor VBA.
3. Następnie kliknij „Normalny” projekt.
4. Kliknij zakładkę „Wstaw” na pasku menu i wybierz „Moduł” z rozwijanego menu.
5. Następnie kliknij dwukrotnie moduł, aby go otworzyć.
6. Wklej w module następujące kody:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Wreszcie, kliknij przycisk „Uruchom” lub naciśnij „F5”.

Otrzymasz taką wiadomość, informującą o wykonaniu zadania.

Znajdź wszystkie jednozdaniowe akapity w wielu dokumentach

1. Na początek musisz umieścić wszystkie dokumenty docelowe w folderze.
2. Następnie zainstaluj i uruchom następujące makro:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. W otwartym oknie „Przeglądaj” wybierz folder, w którym przechowujesz dokumenty i kliknij „OK”.

Następnie makro podświetli wszystkie jednozdaniowe akapity i pozostawi dokumenty otwarte. Jeśli dokument nie zawiera akapitu jednozdaniowego, zostanie zamknięty. Poza tym jest tam okno komunikatu, wskazujące liczbę jednozdaniowych akapitów w każdym dokumencie.

Postępuj w przypadku utraty danych

Błędy użytkownika i nagła przerwa w zasilaniu mogą spowodować śmierć programu Word. Podczas gdy zwinięte słowo może nie tylko wpływać na codzienną pracę, ale także prowadzić do uszkodzenie dokumentuTo wcale nie jest najbardziej irytujący aspekt katastrofy danych. Lepiej od razu skorzystać z narzędzia do naprawy, aby odzyskać dane.

Wprowadzenie autora:

Vera Chen jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym odzyskaj Excela i pdf oprogramowanie do naprawy. po więcej informacji odwiedź www.datanumen.com