Jak szybko wyeksportować całkowity czas spędzony na spotkaniach programu Outlook w każdej kategorii kolorów

Jeśli chcesz utworzyć raport o całkowitym czasie spędzonym na spotkaniach w każdej kategorii kolorystycznej, możesz skorzystać z metody przedstawionej w tym artykule. Pomoże Ci to osiągnąć w krótkim czasie bez konieczności ręcznego liczenia.

Wielu użytkowników jest przyzwyczajonych do rejestrowania większości swoich aktywności w kalendarzu Outlooka. Ponadto, aby łatwiej nimi zarządzać i je rozróżniać, przypisują im kategorie. W takim przypadku niektórzy użytkownicy chcieliby wygenerować raport pokazujący całkowity czas spędzony na elementach kalendarza w każdej kategorii kolorystycznej. Bez wątpienia ręczne liczenie i wprowadzanie danych jest uciążliwe. Dlatego poniżej przedstawiamy sposób, który pozwala to zrobić jednym kliknięciem.

Eksportuj całkowity czas spędzony na spotkaniach w każdej kategorii kolorów

1. W pierwszej kolejności uruchom aplikację Outlook.
2. Następnie, po wejściu do okna programu Outlook, możesz nacisnąć przyciski klawiszy „Alt + F11”.
3. Następnie uzyskasz dostęp do okna „Microsoft Visual Basic for Applications”.
4. Następnie musisz włączyć „Bibliotekę obiektów Microsoft Excel”. Aby to zrobić, kliknij „Narzędzia” > „Odniesienia”.
5. Następnie powinieneś znaleźć i otworzyć moduł, który nie jest używany.
6. Następnie musisz skopiować następujący kod VBA do tego modułu.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Wreszcie możesz uruchomić to makro, bez względu na to, czy klikniesz ikonę „Uruchom” na pasku narzędzi, czy naciśniesz przycisk „F5”.
8. Następnie zostaniesz poproszony o wybranie konkretnego kalendarza.
9. Po wybraniu i naciśnięciu „OK” makro będzie nadal działać. Po zakończeniu pojawi się nowy plik programu Excel, który będzie wyświetlany w tle.
10. Możesz uzyskać do niego dostęp. Będzie wyglądać jak na poniższym zrzucie ekranu:

Uważaj na potencjalne zagrożenia wokół Twojego programu Outlook

Użytkownicy programu Outlook powinni uważać na wszystkie potencjalne zagrożenia, w tym nieznane załączniki wiadomości e-mail, osadzone łącza i błędy ludzkie. W przeciwnym razie Twój program Outlook może zostać uszkodzony w dowolnym momencie. Konieczne jest również regularne tworzenie kopii zapasowych danych programu Outlook i posiadanie specjalistycznego narzędzia do naprawy. DataNumen Outlook Repair jest jednym z najbardziej polecanych narzędzi naprawczych. Może napraw Outlooka problemy w mgnieniu oka.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym uszkodzony mdf i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com