Jak szybko wyeksportować wszystkie załączniki obrazu wiadomości e-mail programu Outlook do arkusza programu Excel

Jeśli chcesz szybko wyeksportować wszystkie załączniki obrazu wiadomości e-mail programu Outlook do arkusza programu Excel, możesz zapoznać się z tym artykułem. Tutaj pokażemy Ci bardziej efektywny sposób niż ręczne eksportowanie.

Gdy otrzymasz wiadomość e-mail zawierającą mnóstwo załączników graficznych i chcesz wykorzystać je do utworzenia raportu w programie Excel, z pewnością szukasz sposobu na eksportowanie tych obrazów do arkusza kalkulacyjnego Excela partiami. Poniżej przedstawimy Ci takie podejście.

Eksportuj wszystkie załączniki do wiadomości e-mail z obrazami do arkusza programu Excel

1. Na początek uzyskaj dostęp do aplikacji Outlook w normalny sposób.
2. Następnie w oknie Outlooka naciśnij klawisze skrótu „Alt + F11”, co spowoduje wyświetlenie okna „Microsoft Visual Basic for Applications”.
3. Na tym ekranie musisz otworzyć nieużywany moduł lub od razu wstawić nowy.
4. Następnie powinieneś skopiować poniższy fragment kodu VBA do tego modułu.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Następnie możesz wyjść z makra.
6. Następnie przejdź do „Plik”> „Opcje”> „Pasek narzędzi szybkiego dostępu”, aby dodać to makro do paska narzędzi szybkiego dostępu.
7. Wreszcie możesz teraz wypróbować to makro.

• Po pierwsze, wybierz lub otwórz źródłową wiadomość e-mail.
• Następnie kliknij przycisk makra na pasku narzędzi Szybki dostęp.
• Po zakończeniu działania makra otrzymasz arkusz programu Excel, pokazany jak na poniższym zrzucie ekranu:

Chroń plik programu Outlook przed uszkodzeniem

Wiadomo, że Outlook jest podatny na korupcję. Dlatego powinniśmy zrozumieć, jak chronić przed uszkodzeniem formularzy programu Outlook. Po pierwsze, aby blokować ataki wirusów, należy zainstalować oprogramowanie antywirusowe i nigdy nie pobierać nieznanego załącznika. Poza tym lepiej zaopatrzyć się w potężne narzędzie naprawcze, takie jak DataNumen Outlook Repair. Może zaoferować najskuteczniejsze lekarstwo w przypadku Uszkodzenie programu Outlook.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym odzyskiwanie sql i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com