Jak automatycznie wyodrębniać osadzone obrazy z określonych przychodzących wiadomości e-mail za pośrednictwem programu Outlook VBA

Jeśli chcesz, aby program Outlook automatycznie wyodrębniał i zapisywał osadzone obrazy z określonych przychodzących wiadomości e-mail, możesz zapoznać się z tym artykułem. Tutaj nauczymy Cię, jak to zrealizować za pomocą kodu VBA.

Niektórzy użytkownicy często muszą wyodrębniać osadzone obrazy z określonych przychodzących wiadomości e-mail i zapisywać je w określonym folderze systemu Windows. Wykonywanie tego ręcznie za każdym razem jest tak kłopotliwe. Dlatego wielu nie może się doczekać, kiedy nauczy się szybkiego i wygodnego podejścia do automatycznego wykonywania tego zadania przez program Outlook. Teraz podzielimy się z wami taką metodą.

Automatyczne wyodrębnianie osadzonych obrazów z określonych przychodzących wiadomości e-mail

1. Najpierw uruchom program Outlook w zwykły sposób.
2. Następnie jak zwykle uruchom edytor VBA programu Outlook z odniesieniem t „Jak uruchomić kod VBA w swoim Outlooku".
3. Później skopiuj i wklej następujący kod VBA do projektu „ThisOutlookSession”.

Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

4. Następnie kliknij podprocedurę „Application_Startup”.
5. Na koniec kliknij klawisz „F5”, aby wywołać to makro.
6. Odtąd za każdym razem, gdy do Skrzynki odbiorczej dotrze nowa wiadomość e-mail, osadzone obrazy będą zapisywane w określonym folderze Windows, jak pokazano na poniższym zrzucie ekranu.

Regularnie czyść duże załączniki

Zaleca się regularne usuwanie dużych załączników z Outlooka. Ma to na celu utrzymanie odpowiedniego rozmiaru pliku Outlook. Większe pliki Outlooka są bardziej podatne na uszkodzenia. Jak wiadomo, uszkodzenie pliku PST jest dość trudne do usunięcia. Możesz najpierw spróbować naprawić je za pomocą narzędzia do naprawy skrzynki odbiorczej. Jednak w większości przypadków to nie zadziała. Jedynym ratunkiem jest wyspecjalizowany specjalista. Naprawa PST narzędzie, takie jak DataNumen Outlook Repairlub odpowiednie profesjonalne usługi odzyskiwania.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym poprawka mdf i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com