Jak wsadowo usunąć wszystkie adresy e-mail z określoną domeną z kontaktów programu Outlook

Czasami możesz chcieć usunąć wszystkie adresy e-mail z określonej domeny ze swoich kontaktów. W tej sytuacji musisz nie chcieć robić tego pojedynczo. Tym samym ta strost nauczy cię znacznie mądrzejszej metody.

Na przykład firma zmienia nazwę. W międzyczasie zmienia się również domena firmy. Jednak w Outlooku zapisałeś wiele kontaktów w tej firmie, których adresy e-mail są w starej domenie. Oczywiście te adresy e-mail są już nieaktualne. Dlatego w tej sytuacji, jeśli chcesz usunąć te adresy e-mail za jednym razem, możesz skorzystać z następującego sposobu.

Usuń zbiorczo wszystkie adresy e-mail z określoną domeną z kontaktów

1. Jaktart, uzyskaj dostęp do edytora Outlook VBA za pomocą skrótu klawiszowego – „Alt + F11”.
2. Następnie w nowym oknie umieść następujący kod VBA w pustym module.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Następnie umieść kursor w podprogramie „BatchRemoveAllEmailAddressesInSpecificDomain”.
4. Na koniec kliknij przycisk klawisza „F5”, aby uruchomić to makro.
5. Następnie wprowadź konkretną domenę w wyskakującym oknie dialogowym.
6. Po kliknięciu „OK” uruchomi się makro.
7. Po zakończeniu otrzymasz wiadomość o wynikach.
8. Teraz możesz sprawdzić kontakty. Wszystkie adresy e-mail z określoną domeną musiały zniknąć.

Zachowaj swój plik programu Outlook

Przy coraz większej liczbie zagrożeń związanych z programem Outlook coraz trudniej jest chronić cenne dane programu Outlook. Na przykład, nie tylko powinieneś wytrwać w regularnym tworzeniu kopii zapasowych danych, ale także musisz uważać na swoje operacje. Nierozsądnie jest łatwo ufać jakimkolwiek e-mailom od nieznanych nadawców. W przeciwnym razie, jeśli zawiera wirusa, plik programu Outlook zostanie zainfekowany. W takim razie musisz spróbować Naprawa programu Outlook za pomocą niezwykłego narzędzia naprawczego, takiego jak DataNumen Outlook Repair.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym wyzdrowieć Sql Server i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com