Jak automatycznie przenosić wiadomości e-mail z określonymi odbiorcami CC w programie Outlook

W rzeczywistości Most z was może mieć nadzieję na utworzenie reguły programu Outlook, aby automatycznie przenosić wiadomości e-mail do określonych odbiorców DW. Ale reguła programu Outlook nie obsługuje sprawdzania odbiorców DW. W tym artykule dowiesz się, jak to zrealizować za pomocą programu Outlook VBA.

Oczywiście niemożliwe jest utworzenie reguły Outlooka do wyszukiwania określonych odbiorców CC. Jak pokazano na poniższym zrzucie ekranu, w przypadku otrzymanych wiadomości e-mail możesz sprawdzić tylko, czy w polu DW znajduje się Twoje imię i nazwisko. Podobnie w przypadku wysyłanych e-maili, nawet jeśli nie ma warunku reguły, aby zaznaczyć pole CC.

Dlatego jeśli chcesz skonfigurować Outlooka, aby automatycznie przenosił wiadomości e-mail do określonych odbiorców CC, musisz poszukać innych środków. Następnie. tutaj nauczymy Cię, jak to osiągnąć za pomocą Outlooka VBA.

Automatycznie przenoś wysłane wiadomości e-mail do określonych odbiorców CC

1. Najpierw przejdź do zakładki „Programista” i kliknij przycisk „Visual Basic”.
2. Następnie otwórz projekt „ThisOutlookSession” i skopiuj do niego następujące kody VBA.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. Następnie należy przystąpić do podpisywania tego kodu i zmiany ustawień makr w zwykły sposób.
4. Na koniec możesz wyjść z okna „Visual Basic”. Następnie wiadomości e-mail z określonymi odbiorcami DW zostaną przeniesione do określonego folderu poczty.

Automatycznie przenoś odebrane wiadomości e-mail do określonych odbiorców CC

Teraz, gdy powyższy kod VBA ma na celu przeniesienie wysłanych wiadomości e-mail z określonymi odbiorcami CC, jeśli chcesz wyszukać określonych odbiorców CC w otrzymanych wiadomościach e-mail, a następnie przenieść je, powinieneś zamiast tego użyć następujących kodów.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Bądź dobrze przygotowany na korupcję programu Outlook

Chociaż Outlook jest bogaty w funkcje, nadal nie może być odporny na korupcję. Dlatego należy zachować czujność wobec wszystkich potencjalnych zagrożeń. Bez wątpienia krytycznym krokiem musi być wykonanie spójnej i aktualnej kopii zapasowej danych programu Outlook. Ponadto należy zachować ok uszkodzone narzędzie do odzyskiwania programu Outlook w pobliżu. Przyda się, jeśli zarówno kopie zapasowe, jak i plik Scanpst.exe zawiodą.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym naprawa SQL Server Błąd pliku mdf i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com