Jak automatycznie wyróżniać ważne e-maile, na które nie odpowiedziałeś w Outlooku

Aby pamiętać o odpowiadaniu na ważne wiadomości e-mail, możesz chcieć, aby program Outlook wyświetlał ważne wiadomości e-mail, na które nie odpowiedziałeś, w określonym kolorze manifestu, aby je wyróżnić. W tym artykule dowiesz się, jak go zdobyć.

Czy kiedykolwiek przegapiłeś ważne e-maile i nie odpowiedziałeś na nie na czas? Jeśli napotkałeś takie problemy, być może będziesz mieć nadzieję, że Outlook może wyróżnić ważne e-maile, na które nie odpowiedziałeś. Teraz, w dalszej części, poprowadzimy Cię, jak to osiągnąć za pomocą VBA. Jeśli nie znasz VBA, zapoznaj się z moim poprzednim artykułem – „Jak uruchomić kod VBA w swoim Outlooku" W międzyczasie.

Automatyczne wyróżnianie ważnych wiadomości e-mail, na które nie odpowiedziałeś

1. Na samym początku uzyskaj dostęp do edytora VBA przez „Alt + F11” w Outlooku.
2. Następnie w nowym oknie skopiuj poniższy kod do projektu „ThisOutlookSession”.

Private WithEvents objSentFolder As Outlook.Folder
Private WithEvents objSentMails As Outlook.Items
Private objInbox As Outlook.Folder

'On startup, auto update the replied status of the emails in Inbox
Private Sub Application_Startup()
    Set objSentFolder = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail)
    Set objSentMails = objSentFolder.Items
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateRepliedStatus(objInbox)
End Sub

'After sending an email, auto update the replied status of the emails in Inbox
Private Sub objSentMails_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       Call UpdateRepliedStatus(objInbox)
    End If
End Sub

Private Sub UpdateRepliedStatus(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objRepliedProperty As Outlook.UserProperty
    Dim strRepliedStatus As String
 
    'Write the replied status to a new user property of emails
    For i = objFolder.Items.Count To 1 Step -1
        If objFolder.Items(i).Class = olMail Then
           Set objMail = objFolder.Items(i)
 
           Set objRepliedProperty = objMail.UserProperties.Find("Replied", True)
           If objRepliedProperty Is Nothing Then
              Set objRepliedProperty = objMail.UserProperties.Add("Replied", olText, True)
           End If
 
           strRepliedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If (Not (strRepliedStatus = 102)) And (Not (strRepliedStatus = 103)) Then
              objRepliedProperty.Value = "No"
           Else
              objRepliedProperty.Value = "Yes"
           End If
 
           objMail.Save
        End If
    Next
End Sub

3. Następnie przesuń kursor do „Application_Startup” makro i naciśnij „F5”.
4. Później zamknij to okno.
5. Następnie wykonaj poniższe czynności, aby utworzyć regułę formatowania warunkowego dla elementów w Skrzynce odbiorczej.

• Najpierw przejdź do folderu „Skrzynka odbiorcza”.
• Następnie przejdź do zakładki „Widok” i kliknij „Ustawienia widoku”.
• W nowym oknie dialogowym kliknij przycisk „Formatowanie warunkowe”.
• W następnym oknie dialogowym "Formatowanie warunkowe" kliknij "Dodaj" i wprowadź nazwę nowej reguły, na przykład "Ważne wiadomości e-mail bez odpowiedzi".
• Później kliknij przycisk „Czcionka…” i ustaw styl i kolor czcionki w wyskakującym oknie dialogowym „Czcionka”.
• Po określeniu czcionki naciśnij „Warunek…” w oknie dialogowym „Formatowanie warunkowe”.
• Następnie na ekranie „Filtr”, w zakładce „Zaawansowane” dodaj dwa filtry.

1. „Ważność” > „równa się” > „Wysoka”
2. „Odpowiedziano” > „jest (dokładnie)” > „Nie”

• Ostatecznie kliknij serię „OK”, aby zapisać tę regułę formatowania.

6. Po powrocie do Inbox wszystkie ważne e-maile, na które nie odpowiedziałeś, zostały wyróżnione odpowiednią czcionką i kolorem.

Nie bądź leniwy w ochronie danych programu Outlook

Niezliczeni użytkownicy wciąż myślą, że uszkodzenie danych nigdy im się nie przydarzy. W rzeczywistości takie pomysły są całkowicie błędne i ryzykowne. Most czasu, drobny błąd może z łatwością spowodować utratę danych. Na przykład, jeśli przypadkowo klikniesz złośliwy link w nieznanych wiadomościach e-mail, plik programu Outlook może zostać zainfekowany wirusem, a nawet ulec uszkodzeniu. W związku z tym należy cały czas zachować ostrożność w zakresie ochrony danych, na przykład regularnie tworzyć kopie zapasowe PST i przygotowywać potężne narzędzie naprawcze, takie jak DataNumen Outlook Repair, Który może naprawić Outlooka problemy w mgnieniu oka.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym odzyskać mdf i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com