2 sposoby szybkiego łączenia wielu dokumentów Word w jeden za pośrednictwem VBA

W tym artykule z przyjemnością udostępnimy Ci 2 sposoby szybkiego połączenia wielu dokumentów Word w jeden za pośrednictwem VBA.

W programie Word jest domyślna wbudowana funkcja, która pomaga użytkownikowi łączyć lub scalać kilka dokumentów w jeden. Szczegóły wyjaśniono w tym artykule: Jak łączyć i scalać wiele dokumentów Word w jeden

Dzięki tej metodzie musisz wykonać kilka kliknięć, a zawartość następnego dokumentu zawsze pojawi się zaraz po poprzedniej. Dlatego chcemy zaoferować szybsze sposoby, aby to zrobić.

Metoda 1: Scal wybrane dokumenty w jeden

1. Przede wszystkim utwórz nowy, pusty dokument.
2. Uruchom edytor VBA w programie Word, naciskając „Alt + F11”.
3. Następnie kliknij „Normalne”.
4. Następnie kliknij „Wstaw”.
5. I wybierz „Moduł”.
6. Kliknij dwukrotnie nowy moduł, aby otworzyć przestrzeń edycji.
7. Wklej tam następujące makro:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Następnie kliknij „Uruchom” lub naciśnij „F5”.
9. Teraz w oknie „Przeglądaj” wybierz wiele plików, naciskając „Ctrl” i kliknij „OK”.
10. Następnie cała zawartość wybranych plików zostanie połączona w nowy dokument, a teksty każdego dokumentu będą zaczynać się na nowej stronie.

Uwaga:

Jak wspomnieliśmy, to makro umieszcza teksty każdego dokumentu na nowej stronie. Ale jeśli chcesz, aby były jedna po drugiej, możesz zmienić niektóre linie kodu w makrze. Po prostu znajdź wiersz „If nEachSelectedFile <nTotalFiles Then”, usuń go, a także następne sześć wierszy.

Metoda 2: Scal wszystkie dokumenty w folderze w jeden

Jeśli masz folder plików do połączenia, to makro powinno działać pięknie.

1. Na początek zainstaluj i uruchom makro zgodnie z opisem w metodzie 1.
2. Następnie zamień makro na to:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Uruchom makro, klikając „Uruchom”.
4. Następnie otworzy się okno „Przeglądaj”. Wybierz folder, w którym przechowujesz wszystkie dokumenty. I kliknij „OK”.

Podobnie, teksty każdego dokumentu zaczynają się na nowej stronie. Aby połączyć je ze sobą, znajdź i usuń linię kodu „.InsertBreak Type:=wdPageBreak”.

Prawidłowo chroń swój dokument Word

Jednym z najlepszych sposobów ochrony dokumentów programu Word jest regularne tworzenie ich kopii zapasowych. Mając kopie zapasowe w ręku, nigdy nie będziesz musiał obawiać się utraty danych. Poza tym wskazane jest również zaopatrzenie się w narzędzie napraw docx jeśli którykolwiek z nich zostanie uszkodzony.

Wprowadzenie autora:

Vera Chen jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym uszkodzony Excel i pdf oprogramowanie do naprawy. po więcej informacji odwiedź www.datanumen.com