2 Metody szybkiego wysyłania wybranych komórek w arkuszu programu Excel jako wiadomość e-mail programu Outlook

Czasami możesz chcieć szybko wstawić wybrane komórki z arkusza programu Excel do wiadomości e-mail programu Outlook i wysłać tę wiadomość e-mail. W tym artykule przyjrzymy się temu życzeniu, aby zaoferować 2 metody.

Mój poprzedni artykuł „2 Szybkie metody wysyłania arkusza programu Excel jako wiadomości e-mail programu Outlook”Nauczył Cię, jak wysłać cały arkusz programu Excel jako wiadomość e-mail. Czasami jednak chcesz wysłać wybrane komórki w arkuszu jako wiadomość e-mail. W odpowiedzi na to wymaganie przedstawimy Ci 2 metody. Możesz wybrać według własnych preferencji.

Metoda 1: Ręczne kopiowanie wybranych komórek do wiadomości e-mail

1. Na początek otwórz plik źródłowy Excel i uzyskaj dostęp do odpowiedniego arkusza kalkulacyjnego Excel.
2. Następnie wybierz komórki, które chcesz wysłać jako wiadomość e-mail programu Outlook.
3. Następnie naciśnij klawisze „Ctrl + C”, aby skopiować wybrane komórki.
4. Następnie uruchom aplikację Outlook.
5. Następnie kliknij przycisk „Nowa wiadomość e-mail” na wstążce „Strona główna”, aby utworzyć nową wiadomość e-mail programu Outlook.
6. Później w nowym oknie wiadomości kliknij sekcję treści wiadomości.
7. A następnie naciśnij klawisze „Ctrl + V”, aby wkleić wcześniej skopiowane wybrane komórki Excela.
8. Na koniec możesz jak zwykle napisać wiadomość e-mail i kliknąć przycisk „Wyślij”, aby ją wysłać.

Metoda 2: Wyślij wybrane komórki jako wiadomość e-mail za pośrednictwem VBA

1. Na samym początku otwórz źródłowy skoroszyt programu Excel.
2. Następnie naciśnij klawisze „Alt + F11”, aby uzyskać dostęp do edytora Excel VBA.
3. W nowym oknie kliknij „Wstaw”> „Moduł”, aby wstawić nowy moduł.
4. Następnie należy włączyć obiekt Microsoft Outlook. Kliknij „Narzędzia” > „Odwołania”. W wyskakującym oknie dialogowym znajdź i zaznacz „Bibliotekę obiektów Microsoft Outlook”.
5. Następnie skopiuj następujący kod VBA do tego modułu.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. W końcu możesz spróbować.

• Najpierw wybierz określone komórki w zwykły sposób.
• Następnie wróć do nowego makra i naciśnij klawisz F5, aby je uruchomić.
• Od razu pojawi się nowa wiadomość e-mail programu Outlook, w której możesz zobaczyć, że wybrane komórki zostały wstawione do treści wiadomości e-mail, jak na poniższym zrzucie ekranu:

Plik PST jest taki sam, jak plik programu Excel

Jak wiemy, pliki Excel i Word są podatne na uszkodzenia. To samo dotyczy pliku PST, który zawiera wszystkie elementy skrzynki pocztowej Outlook. Zabezpieczenie danych PST jest zatem trudnym zadaniem. Jednym z najskuteczniejszych sposobów jest regularne tworzenie kopii zapasowej pliku. Ponadto, aby zapewnić natychmiastową pomoc, warto przygotować doświadczone narzędzie, takie jak… DataNumen Outlook Repair, który jest w stanie odzyskać Outlooka dane bez zerwania potu.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym naprawa mdf i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com