2 szybkie sposoby wyodrębniania sekcji z dokumentu programu Word

W tym artykule zaoferujemy 2 szybkie i łatwe sposoby wyodrębnienia sekcji z dokumentu Word do innego lub kilku.

Dość często zdarza się wyodrębnianie treści z jednego dokumentu do drugiego. W naszym poprzednim artykule omówiliśmy, jak wyodrębnić strony z dokumentu. Szczegółowe informacje można znaleźć w tym artykule: 2 szybkie sposoby wyodrębniania pojedynczych stron z dokumentu programu Word

Dzisiaj pokażemy, jak wyodrębniać według sekcji.    

Metoda 1: Wyodrębnij bieżącą sekcję do nowego dokumentu

1. Najpierw należy umieścić kursor w sekcji docelowej.
2. Następnie naciśnij „Alt + F11”, aby wywołać edytor VBA w programie Word.
3. Następnie w lewej kolumnie kliknij „Normalne”.
4. Na pasku menu kliknij „Wstaw”.
5. Następnie wybierz „Moduł” z tego menu rozwijanego.
6. Kliknij dwukrotnie, aby otworzyć nowy moduł i wklej tam następujące kody:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Następnie kliknij „Uruchom” na pasku menu lub naciśnij „F5”.
8. Następnie pojawi się okno „Przeglądaj”. Wybierz miejsce do przechowywania nowego dokumentu i kliknij „OK”.
9. W polu „Nazwa pliku” wprowadź nazwę nowego pliku i kliknij „OK”.

Teraz wyodrębniłeś sekcję do nowego dokumentu.

Metoda 2: Wyodrębnij każdą sekcję w dokumencie do indywidualnych nowych osób

W ten sposób może pomóc w przetwarzaniu wsadowym wszystkich sekcji w dokumencie. Oczywiście będziemy też potrzebować makra.

1. Na początek otwórz dokument docelowy.
2. Następnie wykonaj czynności opisane w metodzie 1, aby zainstalować i uruchomić makro.
3. Tylko tym razem zamień to makro na to:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Mimo to w oknie „Przeglądaj” wybierz ścieżkę przechowywania i kliknij „OK”.

Napraw irytujące błędy słów

Podczas korzystania z niego często można napotkać błędy programu Word. Może to być irytujące, musimy poświęcić trochę czasu odzyskać słowo tak szybko, jak to możliwe. Ponieważ im dłużej to opóźnimy, tym poważniejsza może być utrata danych. Dlatego zaleca się wcześniejsze skontaktowanie się z narzędziem naprawczym.

Wprowadzenie autora:

Vera Chen jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym uszkodzony plik xls i pdf oprogramowanie do naprawy. po więcej informacji odwiedź www.datanumen.com