როგორ სწრაფად გავიტანოთ ექსპორტი Outlook-ის დანიშვნებზე დახარჯული დრო თითოეულ ფერთა კატეგორიაში

თუ გსურთ შექმნათ ანგარიში იმ დროის შესახებ, რომელსაც დახარჯავთ შეხვედრებზე თითოეულ ფერთა კატეგორიაში, შეგიძლიათ გამოიყენოთ ამ სტატიაში წარმოდგენილი მეთოდი. ის დაგეხმარებათ ამის მიღწევაში სწრაფად, ხელით დათვლის გარეშე.

ბევრი მომხმარებელი მიჩვეულია თავისი აქტივობების უმეტესობის Outlook კალენდარში აღრიცხვას. ასევე, მათი მართვისა და დიფერენცირების გასამარტივებლად, ისინი თითოეულ მათგანს კატეგორიებს ანიჭებენ. ამ შემთხვევაში, ზოგიერთ მომხმარებელს სურს შექმნას ანგარიში, რომელიც აჩვენებს კალენდრის ელემენტებზე დახარჯული დროის საერთო რაოდენობას თითოეული ფერის კატეგორიაში. ეჭვგარეშეა, რომ ხელით დათვლა და შეყვანა პრობლემურია. ამიტომ, აქ ჩვენ გაგიზიარებთ გზას, რომლითაც შეგიძლიათ ამ ამოცანის შესრულება მარტივი დაწკაპუნებით.

შეხვედრებზე დახარჯული დროის ექსპორტი თითოეულ ფერთა კატეგორიაში

1. პირველ რიგში, გაუშვით თქვენი Outlook აპლიკაცია.
2. შემდეგ, Outlook-ის ფანჯარაში შესვლის შემდეგ, შეგიძლიათ დააჭიროთ "Alt + F11" ღილაკებს.
3. ამის შემდეგ, თქვენ მიიღებთ წვდომას "Microsoft Visual Basic აპლიკაციებისთვის" ფანჯარაზე.
4. შემდეგ, თქვენ უნდა ჩართოთ „Microsoft Excel Object Library“. მის გასააქტიურებლად შეგიძლიათ დააჭიროთ „Tools“ > „Reference“.
5. შემდეგ, თქვენ უნდა იპოვოთ და გახსნათ მოდული, რომელიც არ გამოიყენება.
6. ამის შემდეგ, თქვენ უნდა დააკოპიროთ შემდეგი VBA კოდი ამ მოდულში.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. და ბოლოს, თქვენ შეგიძლიათ გაააქტიუროთ ეს მაკრო, არ აქვს მნიშვნელობა ინსტრუმენტთა პანელში „Run“ ხატულაზე დაჭერით ან „F5“ ღილაკის დაჭერით.
8. შემდეგ მოგეთხოვებათ კონკრეტული კალენდრის არჩევა.
9. მას შემდეგ რაც აირჩევთ და დააჭირეთ ღილაკს "OK", მაკრო გააგრძელებს მუშაობას. დასრულების შემდეგ, იქნება ახალი Excel ფაილი, რომელიც გამოჩნდება ფონზე.
10. თქვენ შეგიძლიათ მასზე წვდომა. ეს გამოიყურება შემდეგ ეკრანის სურათზე:

თვალი ადევნეთ პოტენციურ საფრთხეებს თქვენი მსოფლმხედველობის გარშემო

Outlook-ის მომხმარებლებმა ყურადღება უნდა მიაქციონ ყველა პოტენციურ რისკს, მათ შორის უცნობი ელფოსტის დანართებს, ჩაშენებულ ბმულებს და ადამიანურ შეცდომებს. წინააღმდეგ შემთხვევაში, თქვენი Outlook შეიძლება ნებისმიერ დროს დაზიანდეს. ასევე, Outlook-ის მონაცემების რეგულარული სარეზერვო ასლების გაკეთება და სპეციალიზებული სარემონტო ხელსაწყოს შენახვა აუცილებლობაა. DataNumen Outlook Repair ერთ-ერთი ყველაზე რეკომენდებული გამოსასწორებელი ინსტრუმენტია. მას შეუძლია Outlook-ის შეკეთება პრობლემები ერთბაშად.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის დაზიანებული მდფ და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად