როგორ ავტომატურად გადაიტანოთ წერილები CC სპეციფიკურ მიმღებებთან Outlook-ში

სინამდვილეში, თქვენგან უმეტესობას შეიძლება იმედი ჰქონდეს, რომ Outlook-ის წესის შექმნას აპირებთ კონკრეტული CC მიმღებების ელფოსტის ავტომატურად გადასატანად. თუმცა, Outlook-ის წესი არ უჭერს მხარს CC მიმღებების შემოწმებას. ამიტომ, ეს სტატია გასწავლით თუ როგორ განახორციელოთ ეს Outlook VBA-ს გამოყენებით.

ცხადია, შეუძლებელია თქვენ შექმნათ Outlook წესი კონკრეტული CC მიმღებების მოსაძებნად. როგორც ნაჩვენებია შემდეგ სკრინშოტზე, მიღებული ელფოსტისთვის, შეგიძლიათ მხოლოდ შეამოწმოთ, არის თუ არა თქვენი საკუთარი სახელი CC ველში. ანალოგიურად, გაგზავნილი ელფოსტისთვის, არ არსებობს წესის პირობა, რომ შეამოწმოთ CC ველი.

ამიტომ, თუ გსურთ Outlook-ის კონფიგურაცია, რათა ავტომატურად გადაიტანოთ წერილები კონკრეტულ CC მიმღებებთან, თქვენ უნდა მოძებნოთ სხვა საშუალებები. მაშინ. აქ ჩვენ გასწავლით როგორ მიაღწიოთ ამას Outlook VBA-ის საშუალებით.

გაგზავნილი წერილების ავტომატური გადატანა CC კონკრეტულ მიმღებებთან

1. პირველ რიგში, გადადით "დეველოპერი" ჩანართზე და დააჭირეთ ღილაკს "Visual Basic".
2. შემდეგ გახსენით პროექტი "ThisOutlookSession" და დააკოპირეთ მასში შემდეგი VBA კოდები.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. ამის შემდეგ, თქვენ უნდა გააგრძელოთ ამ კოდის ხელმოწერა და მაკრო პარამეტრების შეცვლა, როგორც ყოველთვის.
4. და ბოლოს, შეგიძლიათ გახვიდეთ "Visual Basic" ფანჯრიდან. ამის შემდეგ, წერილები CC კონკრეტულ მიმღებებთან გადავა მითითებულ ფოსტის საქაღალდეში.

მიღებული წერილების ავტომატური გადატანა CC კონკრეტულ მიმღებებთან

ახლა, როდესაც ზემოთ მოყვანილი VBA კოდი მიზნად ისახავს გაგზავნილი წერილების გადატანას კონკრეტულ CC მიმღებებთან, თუ გსურთ მოძებნოთ კონკრეტული CC მიმღებები მიღებულ წერილებში და შემდეგ გადაიტანოთ იგი, ამის ნაცვლად უნდა გამოიყენოთ შემდეგი კოდები.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

იყავით კარგად მომზადებული Outlook კორუფციისთვის

მიუხედავად იმისა, რომ Outlook მდიდარია ფუნქციებით, ის მაინც ვერ იქნება იმუნური კორუფციისგან. ამიტომ სიფხიზლე უნდა იყოთ ყველა პოტენციური რისკის წინააღმდეგ. ეჭვგარეშეა, კრიტიკული ნაბიჯი უნდა იყოს Outlook მონაცემების თანმიმდევრული და განახლებული სარეზერვო ასლის შექმნა. გარდა ამისა, თქვენ უნდა შეინახოთ ა კორუმპირებული Outlook აღდგენის ინსტრუმენტი სიახლოვეს. ეს გამოდგება, თუ ორივე სარეზერვო ასლი და Scanpst.exe ვერ მოხერხდება.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის სარემონტო SQL Server mdf ფაილის შეცდომა და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად