Kuidas eksportida hääletamisstatistikat kiiresti Outlooki meilist Exceli töölehele

Outlooki lahendused September 29, 2025

Kui olete saatnud hääletusnuppudega meili, võiksite pärast seda, kui adressaadid on teile vastused saatnud, üle lugeda ja eksportida hääletusstatistika Exceli töölehel. Niisiis, selles lkost, õpetame teile, kuidas seda kiiresti saavutada.

Outlook on nii võimas, et pakub isegi hääletamisfunktsiooni. Minu eelmine artikkel "MS Outlooki oskuslik kasutamine hääletamiseks” on õpetanud, kuidas seda tõhusalt kasutada. Samuti most Mõne aja pärast võite pärast hääletamist jätkata hääletusstatistika eksportimist Exceli töölehel, mis on tingitud mõnest põhjusest, näiteks soovist statistikat välja printida. Kuid Outlook seda vaikimisi ei toeta. Seetõttu õpetame teile järgnevalt, kuidas seda korgina realiseerida.

Eksportige hääletamisstatistika kiiresti Outlooki meilist Exceli töölehele

Eksportige hääletusstatistika meilis Exceli töölehel

  1. Käivitage kohe alguses oma Outlooki rakendus.
  2. Seejärel peaksite Outlooki peaaknas vajutama klahvikombinatsiooni Alt + F11.
  3. Järgmisena peaksite aknas "Microsoft Visual Basic for Applications" lubama "Microsoft Excel Object Library”. Klõpsake "Tööriistad" > "Viide". Seejärel märkige hüpikakna dialoogiboksis märkeruut „Microsoft Excel Object Library” ja viimasena vajuta „OK”.
  4. Pärast seda saate sisestada uue mooduli või avada mittekasutuses oleva.
  5. Seejärel kopeerige ja kleepige sellesse moodulisse järgmised VBA koodid.
Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

VBA kood – hääletamisstatistika eksportimine Outlooki meilist Exceli töölehel

  1. Pärast seda lisage mugavaks juurdepääsuks uus makro kiirpääsu tööriistaribale.
  2. Lõpuks võite proovida.
  • Esiteks valige hääletusnuppe sisaldav lähtemeil.
  • Seejärel klõpsake kiirjuurdepääsu tööriistaribal makronuppu.
  • Kui see makro on töötamise lõpetanud, saate sirvida eelmääratletud kohalikku kausta, milles näete uut Exceli töövihikut.
  • Avage see Exceli töövihik. Nüüd näete hääletamise statistikat, mis on näidatud alloleval pildil:Eksporditud hääletamisstatistika

Keegi ei saa Outlooki vigu põhjalikult vältida

Kuigi Outlook on varustatud mitmesuguste võimalustega, pole sellist funktsiooni, mis aitaks meil Outlooki vigu vältida. Outlooki tõrkeid võivad põhjustada igasugused tegurid. Näiteks kui väljute sageli Outlookist valesti, kannatate tõenäoliselt selle all PST korruptsioon. Sellise stsenaariumi korral ei jää teil muud üle, kui kasutada mõnda tõhusat tööriista oma PST-faili päästmiseks, näiteks DataNumen Outlook Repair. See on pälvinud oma kõrge taastumismäära tõttu palju kiitust.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas rikutud mdf ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom

Kommentaarid on suletud.