Kuidas eksportida mitu Outlooki meili VBA kaudu ühte Wordi dokumenti

Outlooki lahendused September 29, 2025

Kui soovite eksportida mitu Outlooki meilisõnumit ühte Wordi dokumenti, saate kasutada selles artiklis näidatud VBA-koodi. See võib aidata teil seda ülesannet mõne sekundiga täita.

Olen oma eelmises artiklis kunagi tutvustanud, kuidas Outlooki meilisõnumit Wordi dokumendiks teisendada - "2 tõhusat meetodit Outlooki meili teisendamiseks Wordi dokumendiks”. Kuid mõlemad 2 tähendab, mis on mainitud selles lkost on abitu juhul, kui soovite eksportida palju e-kirju ühte Wordi dokumenti. Seetõttu õpetame teile siin teist viisi. Nüüd lugege edasi, et seda üksikasjalikult mõista.

Eksportige mitu Outlooki meili VBA kaudu ühte Wordi dokumenti

Eksportige mitu Outlooki e-kirja pakettidena ühte Wordi dokumenti

  1. Et start koos käivitage oma Outlooki programm.
  2. Seejärel peate pärast Outlooki põhiakna sisenemist vajutama klahvikombinatsiooni Alt + F11.
  3. Järgmisena saate juurdepääsu Outlooki VBA redaktorile, milles peaksite avama tühja mooduli.
  4. Seejärel kopeerige allolev VBA kood avatud mooduli aknasse.
Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

VBA kood – mitme Outlooki meili pakkimiseks eksportimine ühte Wordi dokumenti

  1. Pärast seda on parem lisada see uus VBA projekt kiirpääsu tööriistaribale või lindile.
  2. Lõpuks võite proovida.
  • Esiteks valige mitu Outlooki meili.
  • Seejärel leidke äsja lisatud makronupp ja klõpsake sellel.
  • Kui teilt küsitakse käsku „Täielik”, saate uue Wordi dokumendi leidmiseks sirvida eelmääratletud kohalikku kausta.
  • Avage see dokument, kus näete, et kõik valitud meilid on eksporditud.

Hoidke võimas taastamistööriist läheduses

Vaatamata paljudele funktsioonidele ei saa Outlook siiski vigade eest immuunne olla. Kui olete harjunud tõrked rahule jätma, kui need kuhjuvad, tekib Outlooki krahh kindlasti. Sel hetkel on oluline uuesti kasutada võimsat ja tõhusat taastamisvahendit, nagu DataNumen Outlook Repair. See on hästi kursis PST parandus. Niikaua kui seda kasutate, ei pea te enam muretsema väljavaadete andmete kadumise pärast.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas rikutud mdf ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom

Kommentaarid on suletud.