Kuidas saata kõik töölehed ühes Exceli töövihikus pakettidena eraldi Outlooki meilidena

Kui soovite saata kõik Exceli töövihiku töölehed eraldi Outlooki meilidena, saate kasutada selles artiklis kirjeldatud meetodit. See võib aidata teil seda hulgi realiseerida, ilma tülikat ükshaaval saatmata.

Minu eelmises postituses "2 kiirmeetodit Exceli töölehe saatmiseks Outlooki meilina”, saate teada kaks võimalust ühe Exceli töölehe e-posti teel saatmiseks. Kui soovite saata kõik ühe töövihiku töölehed eraldi e-kirjadena partiidena, on ükskõik kumma selles postituses mainitud vahendi kasutamine üsna tüütu ja tülikas. Seega tutvustame siin teist võimalust, mis võimaldab sellist „paki saatmist“ kiiresti teostada.

Pakkides saatke kõik töölehed ühes Exceli töövihikus eraldi meilidena

1. Kõigepealt peaksite avama Exceli lähtekoodi töövihiku.
2. Seejärel peaksite pärast Exceli akna sisenemist puudutama klahvi "Alt + F11" otseteid.
3. Järgmisena kuvatakse teine ​​aken nimega "Microsoft Visual Basic for Applications".
4. Selles peate avama kasutamata mooduli või sisestama uue mooduli.
5. Seejärel saate sellesse moodulisse kopeerida järgmise VBA koodi.

Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

6. Pärast seda saate selle makro käivitada, vajutades klahvi F5 või klõpsates tööriistaribal ikooni "Käivita".
7. Outlookis kuvatakse korraga meilid, mis vastavad kõigile selle Exceli töövihiku töölehtedele.
8. Lõpuks saate uuesti kontrollida kõiki e-kirjade üksikasju ja klõpsata e-kirjade väljasaatmiseks nuppu "Saada".

Kui varukoopiaid pole, kasutage tõhusat taastetööriista

Üha enam kasutajaid on mõistnud andmete varundamise tähtsust. Niikaua kui olete oma PST-faili varundanud, PST taastamine pärast kahju on üsna lihtne. Kuid kui tõhusat ja ajakohast PST-varukoopiat pole, ei jää teil muud üle, kui kasutada välist PST-parandustööriista, näiteks DataNumen Outlook Repair. See suudab kahjustatud PST-faile imelihtsalt parandada.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas sql-i taastamine ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom