Kuidas automaatselt saata teavitusmeili, kui konkreetne ülesanne on Outlookis täidetud

Outlooki lahendused September 29, 2025

Pärast ülesande täitmist Outlookis võivad paljud kasutajad soovida saata teavitusmeili, et teavitada kedagi, näiteks ülemust. Meili käsitsi saatmine võtab aega. See artikkel tutvustab kiiret meetodit seda tüüpi meilide automaatseks saatmiseks.

Artiklist “4 kiiret sammu oma Outlookis teistele ülesande määramiseks”, võite teada, et kui ülesande on teile määranud teie ülemus ja nad on eelnevalt nõudnud olekuteadet (nagu alloleval ekraanipildil), saavad nad automaatselt aruandemeili.Nõua ülesande oleku aruannet

Kui aga ülesanne on just ise loodud, ei saada Outlook kunagi kellelegi teavitusmeili, kui märgite selle lõpetatuks. Sel juhul, kui soovite saata oma tööst teatamiseks teavitusmeili, peate seda tegema käsitsi. Kuid järgmiste VBA-koodidega saate lasta Outlookil seda automaatselt täita.

Saatke automaatne teavitusmeil, kui konkreetne ülesanne on täidetud

  1. Alguses peaksite start Outlook ja minge vahekaardile „Arendaja”.
  2. Seejärel leidke ja klõpsake nuppu "Visual Basic". Ilmub uus aken "Microsoft Visual Basic for Applications".
  3. Pärast seda topeltklõpsake projekti "ThisOutlookSession" avamiseks ja seejärel kopeerige sellesse järgmised VBA koodid.
Public WithEvents olItems As Outlook.Items

Private Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderTasks).Items
End Sub

Private Sub olItems_ItemChange(ByVal Item As Object)
    Dim obApp As Outlook.Application
    Dim olMail As Outlook.MailItem
    Dim Recip As String
 
    'Replace "test" as per your needs
    If InStr(LCase(Item.Subject), "test") > 0 And Item.Complete = True Then
       'Replace with your desired contact
       Recip = "John Smith"
       If MsgBox("Do you want to send a report to " & Recip & " ?", vbYesNo + vbQuestion, "Confirm Sending Report") = vbYes Then
          Set obApp = Outlook.Application
          Set olMail = obApp.CreateItem(olMailItem)
          With olMail
               .To = Recip
               .Subject = "Complete: " & Item.Subject
               .Body = "Dear Mr. Smith" & vbCrLf & "I've completed this task in " & DateDiff("d", Item.CreationTime, Now) & " day" & Chr(40) & "s" & Chr(41) & "." & vbCrLf & vbCrLf & "Task Name: " & Item.Subject & vbCrLf & "Start Date: " & Item.StartDate & vbCrLf & "Due Date: " & Item.DueDate & vbCrLf & "Creation Time: " & Item.CreationTime & vbCrLf & "Completed Time: " & Now & vbCrLf & vbCrLf & "Task Details: " & vbCrLf & Item.Body
               .ReadReceiptRequested = True
               'To directly send it,use ".Send" instead
               .Display
          End With
       End If
    End If
End Sub

Kopeerige VBA-koodid jaotisesse ThisOutlookSession

  1. Seejärel jätkake selle koodi allkirjastamisega ja muutke makro sätteid, et lubada ainult digitaalselt allkirjastatud makrosid.
  2. Lõpuks saate praegusest aknast väljuda ja proovida.
  • Kui märgite ülesande lõpetatuks, saate sõnumi, nagu järgmine pilt:Kinnitage aruande saatmine
  • Kui klõpsate nupul "Jah", avaneb uus teade, mis on näidatud alloleval pildil:Teavitusmeil

Märge: Kui asendate ".display" reaga ".Send", saadetakse see meil otse välja, ilma et seda kuvatakse.

Pöörake tähelepanu tundmatute meiliaadresside sõnumitele

Olete kindlasti saanud palju e-kirju tundmatutelt aadressidelt. Soovitatav on seda tüüpi meilidega ettevaatlik olla. Põhjus on selles, et need võivad tunduda kahjutud, kuid sisaldavad pahatahtlikke linke, manuseid või makrosid. Pärast nende klõpsamist või avamist võib teie Outlook nakatuda. Sel hetkel pole teil Outlooki andmete tagasi saamiseks muud valikut kui kasutada tähte kahjustatud Outlooki andmete parandamise utiliitNagu DataNumen Outlook Repair.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas SQL mdf probleemi parandamine ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom

Kommentaarid on suletud.