3 kiiret viisi tühjade ridade ja veergude kustutamiseks sõnatabelist

Selles postituses selgitame teile 3 kiiret viisi Wordi tabeli tühjade ridade ja veergude kustutamiseks.

Tabelid on dokumendi jaoks hädavajalikud, eriti erinevat tüüpi andmete hoidmisel. Mõnikord võib pikk tabel ületada lehekülge ja ulatuda mitmele. Nii et kui tabel muutub pikaks ja keeruliseks, saate selle lihtsustamiseks võtta meetmeid. Näiteks saate kustutada mittevajalikud tühjad read ja veerud.

Siin on 3 meetodit, mida saate kasutada.

1. meetod: kustutage tühjad read ja veerud käsitsi

1. Esiteks valige tühjalt rida või veerg.
2. Seejärel paremklõpsake kontekstimenüü avamiseks. Valige menüüst vastavalt "Kustuta read" või "Kustuta veerud".

Kahjuks ei saa te valida mitut mittejärjestikust rida või veergu ja neid sel viisil koos kustutada. Selle nõudmise kohta saate vaadata meie eelmist artiklit: 5 kiiret meetodit mitme rea või veeru kustutamiseks oma Wordi tabelis

2. meetod: kustutage tabelis kõik tühjad read ja veerud

1. meetodil on oma piirang. Seega pakume teile võimalust VBA-koodide kaudu tabelist ridade ja veergude eemaldamiseks.

1. Alustuseks asetage kursor sihttabeli sisse.
2. Teiseks käivitage VBA redaktor, vajutades "Alt + F11".
3. Redaktoris klõpsake esmalt "Tavaline" projekt.
4. Seejärel klõpsake menüüribal vahekaarti "Sisesta".
5. Valige rippmenüüst "Moodul".
6. Mooduli avamiseks topeltklõpsake ja kleepige sinna järgmised koodid:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Lõpuks klõpsake menüüribal nuppu "Käivita" või vajutage "F5".

Mõne sekundi pärast eemaldatakse tabelist kõik tühjad read ja veerud.

3. meetod: kõigis dokumendi tabelites olevate tühjade ridade ja veerude partiide kustutamine

1. Kõigepealt korrake makro installimiseks ja käivitamiseks meetodi 2 samme.
2. Ainult seekord asendage see makro järgmisega:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Taasta kahjustatud dokument

Tänapäeval on kaotatud andmete taastamiseks rohkem kui üks viis. Näiteks on varukoopiate kasutamine alati teie peamine prioriteet. Kui see ei rahulda teie vajadust uusima teabe taastamiseks, võite proovida järgmist. doc remont vahend.

Autori sissejuhatus:

Vera Chen on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas xlsx remont ja pdf tarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom