2 meetodit kõigi Outlookis e-posti aadressita kontaktide pakkimiseks kustutamiseks

Kui leiate, et mõnel kontaktil pole teie Outlookis e-posti aadressi, võiksite töödelda iga kontaktikausta, et kõik sellised kontaktid kustutada. See postitus jagab teiega kahte viisi.

Võib-olla on teie Outlookis palju kontakte ja mõnel neist pole meiliaadressi. Kui arvate, et need pole enam kasulikud, peate lootma kustutada kõik kontaktid ilma e-posti aadressita. Tavalisel viisil saate nende leidmiseks kasutada kiirotsingut ja seejärel need käsitsi kustutada, nagu järgmine meetod 1. Siiski on see pisut tüütu. Seetõttu õpetame 2. meetodis teile veel üht tõhusamat viisi.

1. meetod: käsitsi kustutamine pärast e-posti aadressita kontaktide leidmist

1. Alustamiseks vajutage klahvikombinatsiooni „Ctrl + 3”, et pääseda juurde kontaktide paneelile.
2. Seejärel klõpsake otsingukastis.
3. Järgmisena klõpsake tekkival lindil "Otsing" nuppu "Kõik kontaktandmed".
4. Seejärel klõpsake valikul „On aadress” > „On meiliaadress”.
5. Pärast seda lisatakse otsingukasti kriteerium "EI e-posti aadressid:=[]". Peate eemaldama "EI".
6. Seejärel loetletakse kõik kontaktid, millel pole meiliaadressi.
7. Nüüd peaksite otsingutulemustes kontaktid käsitsi valima, nii et loendis peavad olema ka teie kontaktirühmad.
8. Lõpuks vajutage kõigi valitud kontaktide kustutamiseks klahvi "Del".

2. meetod: kustutage VBA abil kõik kontaktid ilma e-posti aadressita

1. Kõigepealt puudutage Outlookis VBA redaktori käivitamiseks klahvi Alt + F11.
2. Kopeerige uuel ekraanil järgmine VBA kood moodulisse.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Hiljem klõpsake alamprogrammil „BatchDeleteAllContactsWithoutEmailAddress”.
4. Lõpuks vajutage selle makro käivitamiseks klahvi "F5".
5. Kui see on lõppenud, saate tulemuste kohta teate, nagu alloleval pildil.
6. Kõik ilma e-posti aadressita kontaktid on teisaldatud kausta "Kustutatud üksused".

Hoidke kõigist võimalikest riskidest kaugel

Outlook võib kahjustuda mitmesuguste tegurite, näiteks viiruste, kasutajavead, tarkvaratõrgete ja riistvaratõrgete tõttu. Peate olema vastumeelne Outlooki kahjustuste suhtes, seega peate kõiki neid potentsiaalseid riske eemal hoidma. Näiteks peate arvutisse installima võimsa viirusetõrjetarkvara. Lisaks peate oma Outlooki andmeid regulaarselt varundama. Viimaseks, kuid mitte vähem tähtsaks, valmistage parem ette tugev ja usaldusväärne remonditööriist, näiteks DataNumen Outlook Repair. See võib teie korrumpeerunud PST faili hõlpsalt.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas SQL Server korruptsioon ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom