So exportieren Sie schnell die Gesamtzeit, die für die Outlook-Termine in jeder Farbkategorie aufgewendet wurde

Wenn Sie einen Bericht über die Gesamtzeit erstellen möchten, die Sie für die Termine in den einzelnen Farbkategorien aufgewendet haben, können Sie die in diesem Artikel beschriebene Methode verwenden. Dies kann Ihnen dabei helfen, dies in kurzer Zeit zu erreichen, ohne manuell zählen zu müssen.

Viele Nutzer sind es gewohnt, ihre Aktivitäten im Outlook-Kalender zu protokollieren. Um diese besser zu verwalten und zu unterscheiden, ordnen sie ihnen Kategorien zu. Manche Nutzer möchten nun einen Bericht erstellen, der die Gesamtzeit für die Kalendereinträge in jeder Farbkategorie anzeigt. Das manuelle Zählen und Eingeben ist zweifellos mühsam. Daher stellen wir Ihnen hier eine Methode vor, mit der sich diese Aufgabe mit nur einem Klick erledigen lässt.

Exportieren Sie die Gesamtzeit, die für die Termine in jeder Farbkategorie aufgewendet wurde

1. Starten Sie zunächst Ihre Outlook-Anwendung.
2. Nachdem Sie das Outlook-Fenster aufgerufen haben, können Sie auf die Tasten „Alt + F11“ tippen.
3. Anschließend erhalten Sie Zugriff auf das Fenster "Microsoft Visual Basic für Applikationen".
4. Als Nächstes müssen Sie die „Microsoft Excel-Objektbibliothek“ aktivieren. Klicken Sie dazu auf „Tools“ > „Verweise“.
5. Dann sollten Sie ein Modul finden und öffnen, das nicht verwendet wird.
6. Danach müssen Sie den folgenden VBA-Code in dieses Modul kopieren.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Schließlich können Sie dieses Makro auslösen, unabhängig davon, ob Sie in der Symbolleiste auf das Symbol „Ausführen“ klicken oder die Taste „F5“ drücken.
8. Anschließend werden Sie aufgefordert, einen bestimmten Kalender auszuwählen.
9. Nachdem Sie „OK“ ausgewählt und gedrückt haben, wird das Makro weiter ausgeführt. Nach Abschluss des Vorgangs wird im Hintergrund eine neue Excel-Datei angezeigt.
10. Sie können darauf zugreifen. Es sieht wie folgt aus:

Halten Sie Ausschau nach potenziellen Bedrohungen in Ihrem Outlook

Outlook-Benutzer sollten alle potenziellen Risiken berücksichtigen, einschließlich unbekannter E-Mail-Anhänge, eingebetteter Links und menschlicher Fehler. Andernfalls kann Ihr Outlook jederzeit beschädigt werden. Regelmäßige Outlook-Datensicherungen und ein spezielles Reparaturwerkzeug sind ebenfalls erforderlich. DataNumen Outlook Repair ist eines der am meisten empfohlenen Reparaturwerkzeuge. Es kann Outlook reparieren Probleme im Handumdrehen.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich beschädigtes mdf und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX