So exportieren Sie schnell einen Outlook-Ordner mit allen Unterordnern und Elementen in einen Windows-Ordner

Manchmal möchten Sie möglicherweise einen Outlook-Ordner mit allen Unterordnern und Elementen stapelweise in einen Windows-Ordner exportieren. In diesem Artikel erfahren Sie, wie Sie Outlook VBA anwenden.

Wenn Sie einen Outlook-Ordner mit allen Elementen in derselben Ordnerstruktur auf ein lokales Laufwerk exportieren möchten, wird das manuelle Speichern und Exportieren viel Zeit in Anspruch nehmen. Warum greifen Sie also nicht auf andere Mittel zurück, z. B. Exporttools oder VBA-Codes? Hier werden wir Ihnen einen solchen VBA-Code vorstellen. Es wird Ihnen erlauben, es wie eine Brise zu erreichen.

Exportieren Sie alle Unterordner und Elemente in einem Outlook-Ordner in einen Windows-Ordner

1. Starten Sie als Erstes Ihr Outlook-Programm.
2. Drücken Sie dann im Outlook-Hauptfenster die Tastenkombinationen „Alt + F11“.
3. Anschließend wird das Fenster "Microsoft Visual Basic für Applikationen" angezeigt.
4. Als nächstes müssen Sie ein leeres Modul öffnen und die folgenden VBA-Codes darin kopieren.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Danach müssen Sie sicherstellen, dass Ihr Outlook Makros in den Makroeinstellungen zulässt.
6. Schließlich können Sie es versuchen.

• Zunächst zurück zum neuen Makrofenster.
• Klicken Sie anschließend in die Unterroutine "ExportFolderWithAllItems".
• Drücken Sie dann die Taste F5, um dieses Makro auszuführen.
• Danach müssen Sie einen bestimmten Ordner auswählen.
• Wenn Sie die Meldung "Vollständig" erhalten, können Sie auf den vordefinierten lokalen Ordner zugreifen. Sie werden feststellen, dass alle Elemente in derselben Ordnerstruktur gespeichert wurden.

Verhindern Sie Datenverlust durch Outlook-Abstürze

Vielleicht sind Sie schon einmal auf häufige Outlook-Abstürze gestoßen. Meistens funktioniert Outlook nach einem Neustart wieder normal. Es kann jedoch auch vorkommen, dass Ihre PST-Datei beschädigt wird. In diesem Fall versuchen Sie natürlich, Ihre PST-Daten wiederherzustellen, beispielsweise mithilfe eines geeigneten Tools. DataNumen Outlook Repair. Es ist in der Lage Outlook reparieren Fehler und extrahieren Daten aus kompromittierten PST-Dateien, ohne ins Schwitzen zu geraten.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich SQL Server Reparatur- und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX