So exportieren Sie schnell alle Hyperlinks in mehreren Outlook-E-Mails nach Excel

Wenn Sie alle Hyperlinks in einer oder mehreren E-Mails extrahieren müssen, ist es umständlich, sie einzeln zu kopieren. Dieser Beitrag zeigt Ihnen eine Methode, mit der Sie schnell alle Hyperlinks aus mehreren E-Mails nach Excel exportieren können.

Aus bestimmten Gründen, z. B. zum Protokollieren der Hyperlinks in allen gesendeten E-Mails, müssen Sie die Hyperlinks extrahieren. Ohne Zweifel ist es nicht ratsam, sie manuell zu extrahieren und zu kopieren. Sie müssen sich nach einem viel intelligenteren Ansatz sehnen, z. B. die Verwendung von VBA. Hier stellen wir Ihnen einen solchen VBA-Code vor, der in der Lage ist, alle Hyperlinks in vielen E-Mails mit einem einfachen Klick nach Excel zu exportieren.

Exportieren Sie alle Hyperlinks in mehreren E-Mails nach Excel

1. Starten Sie zunächst Ihr Outlook-Programm wie gewohnt.
2. Dann müssen Sie im Outlook-Fenster die Tasten "Alt + F11" drücken.
3. Sie erhalten sofort Zugriff auf den Outlook VBA-Editor.
4. Anschließend müssen Sie sowohl die „Microsoft Word-Objektbibliothek“ als auch die „Microsoft Excel-Objektbibliothek“ aktivieren. Klicken Sie dazu auf „Extras“ > „Verweise“ und aktivieren Sie die Bibliotheken im Popup-Dialogfeld.
5. Als nächstes müssen Sie ein unbenutztes Modul öffnen, in dem Sie den untenstehenden VBA-Code in dieses Modul kopieren müssen.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Danach können Sie das aktuelle VBA-Editorfenster verlassen.
7. Greifen Sie später auf "Outlook-Optionen" zu, um die Symbolleiste für den Schnellzugriff anzupassen, um das neu hinzugefügte Makro zur Symbolleiste für den Schnellzugriff hinzuzufügen.
8. Endlich können Sie einen Schuss machen:

• Wählen Sie zunächst in der E-Mail-Liste die E-Mails aus, deren Hyperlinks Sie extrahieren möchten.
• Klicken Sie dann in der Symbolleiste für den Schnellzugriff auf die Makroschaltfläche.
• Wenn das Makro abgeschlossen ist, erhalten Sie eine Excel-Datei wie in der folgenden Abbildung:

Unerwartete Outlook-Probleme beheben

Outlook-Probleme können gelegentlich ohne Vorwarnung auftreten. Kleinere Fehler lassen sich jedoch in der Regel durch einen einfachen Neustart beheben. Reparaturwerkzeug für den Posteingang. Wenn jedoch ernsthafte Probleme auftreten, werden die internen Mittel keine Auswirkungen haben. An dieser Stelle ist Ihr letzter Ausweg definitiv ein seriöseres und robusteres Werkzeug, wie z DataNumen Outlook Repair.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich beschädigtes mdf und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX