So exportieren Sie schnell die Details aller Mitglieder in einer Outlook-Kontaktgruppe nach Excel

Standardmäßig können Sie nur die Mitgliedsnamen und E-Mail-Adressen in einer Kontaktgruppe anzeigen. Wenn Sie weitere Informationen zu den Mitgliedern erhalten möchten, können Sie die in diesem Artikel beschriebene Methode verwenden.

Wenn Sie auf eine Kontaktgruppe doppelklicken, um sie zu öffnen, werden in ihrem Fenster nur die Namen und E-Mail-Adressen der Gruppenmitglieder angezeigt. Sie können keine anderen Details der Mitglieder wie Firma, Berufsbezeichnung, Telefonnummer oder Geschäftsadresse usw. abrufen. Um diese Details zu erhalten, müssen Sie im Allgemeinen die Kontakte, die den Mitgliedern entsprechen, manuell in Ihrem Kontaktordner finden. Es ist zu lästig. Hier zeigen wir Ihnen einen Teil des VBA-Codes, mit dem diese Details schnell in eine Excel-Arbeitsmappe exportiert werden können.

Exportieren Sie die Details aller Mitglieder in einer Kontaktgruppe nach Excel

1. Zu starStarten Sie mit mit Ihre Outlook-Anwendung.
2. Dann sollten Sie die Tastenkombinationen „Alt + F11“ im Outlook-Hauptfenster drücken.
3. Als nächstes müssen Sie im neuen Fenster "Microsoft Visual Basic für Applikationen" ein nicht verwendetes Modul öffnen oder direkt ein neues Modul einfügen.
4. Kopieren Sie anschließend den folgenden VBA-Code und fügen Sie ihn in dieses Modul ein.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Anschließend können Sie das neue VBA-Projekt zur bequemen Überprüfung zur Symbolleiste oder zum Menüband für den Schnellzugriff hinzufügen.
6. Stellen Sie später die Sicherheitsstufe Ihres Outlook-Makros auf niedrig ein.
7. Letztendlich können Sie es versuchen.

• Wählen Sie zunächst eine Kontaktgruppe aus.
• Drücken Sie dann die Makrotaste in der Symbolleiste oder im Menüband für den Schnellzugriff.
• Das Makro wird sofort ausgeführt.
• Wenn es fertig ist, erhalten Sie die Aufforderung "Vollständig!"
• Danach können Sie in den vordefinierten lokalen Zielordner wechseln, in dem Sie eine neue Excel-Datei finden.
• Wenn Sie es öffnen, werden die Kontaktdaten der Gruppenmitglieder wie im folgenden Screenshot angezeigt:

Keine Panik angesichts von Outlook-Problemen

Niemand ist bereit, Outlook-Probleme zu akzeptieren, unabhängig von der Popup-Fehlermeldung oder beschädigtes Outlook Datendatei. Daher neigen Benutzer dazu, in Panik zu geraten, wenn sie auf Outlook-Probleme stoßen. Wenn Sie in diesem Fall ruhig bleiben möchten, sollten Sie zwei Notwendigkeiten in der Hand haben. Eine davon sind aktuelle Outlook-Datensicherungen. Die andere ist eine leistungsstarke Outlook-Fix-Software wie DataNumen Outlook Repair.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich SQL-Wiederherstellung und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX