Batch-Export mehrerer Outlook-E-Mails in ein Word-Dokument über VBA

Wenn Sie mehrere Outlook-E-Mails stapelweise in ein einziges Word-Dokument exportieren möchten, können Sie den in diesem Artikel gezeigten VBA-Code verwenden. Es kann Ihnen helfen, diese Aufgabe innerhalb von Sekunden zu erledigen.

In meinem vorherigen Artikel habe ich jemals vorgestellt, wie eine Outlook-E-Mail in ein Word-Dokument konvertiert wird.2 Effektive Methoden zum Konvertieren einer Outlook-E-Mail in ein Word-Dokument”. Beide 2 Mittel, die in diesem p erwähnt werdenost ist hilflos, wenn Sie mehrere E-Mails stapelweise in ein Word-Dokument exportieren möchten. Daher werden wir Ihnen hier einen anderen Weg zeigen. Lesen Sie jetzt weiter, um es ausführlich zu verstehen.

Batch-Export mehrerer Outlook-E-Mails in ein Word-Dokument

1. Zu starStarten Sie mit mit Ihr Outlook-Programm.
2. Nachdem Sie das Outlook-Hauptfenster aufgerufen haben, müssen Sie die Tasten „Alt + F11“ drücken.
3. Als Nächstes erhalten Sie Zugriff auf den Outlook VBA-Editor, in dem Sie ein leeres Modul öffnen sollten.
4. Kopieren Sie anschließend den folgenden VBA-Code in das geöffnete Modulfenster.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Danach sollten Sie dieses neue VBA-Projekt besser zur Symbolleiste oder Multifunktionsleiste für den Schnellzugriff hinzufügen.
6. Letztendlich können Sie es versuchen.

• Wählen Sie zunächst mehrere Outlook-E-Mails aus.
• Suchen Sie dann die neu hinzugefügte Makroschaltfläche und klicken Sie darauf.
• Nachdem Sie zur Eingabe von "Vollständig" aufgefordert werden, können Sie zum vordefinierten lokalen Ordner navigieren, um ein neues Word-Dokument zu finden.
• Öffnen Sie dieses Dokument, in dem Sie sehen können, dass alle ausgewählten E-Mails exportiert wurden.

Halten Sie ein mächtiges Wiederherstellungstool in der Nähe

Ungeachtet zahlreicher Funktionen kann Outlook immer noch nicht vor Fehlern gefeit sein. Wenn Sie es gewohnt sind, Fehler in Ruhe zu lassen und sich zu häufen, tritt definitiv ein Outlook-Absturz auf. An diesem Punkt ist es wichtig, auf ein mächtiges und effektives Wiederherstellungswerkzeug wie z DataNumen Outlook Repair. Es ist gut versiert PST beheben. Solange dies der Fall ist, müssen Sie sich keine Gedanken mehr über den Verlust von Outlook-Daten machen.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich beschädigtes mdf und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX