So löschen Sie alle gelesenen Belege in Ihrem Outlook im Stapel

Um zu bestätigen, dass die Empfänger Ihre E-Mail gelesen haben, können Sie beim Verfassen der E-Mail eine Lesebestätigung anfordern. In dieser Situation ist Ihre Mailbox möglicherweise mit solchen Lesebestätigungen gefüllt. Nun, diese post Hier erfahren Sie, wie Sie sie dauerhaft stapelweise löschen können.

Nach dem Lesen des Artikels “So löschen Sie alle Lieferbelege in Ihrem Outlook im Stapel„Vielleicht denken Sie über den Ansatz nach, alle gelesenen Belege in großen Mengen zu löschen. In der Tat ist der offensichtliche Unterschied zwischen den beiden Arten von Quittungen ihre Themen. Der Lieferschein enthält im Betreff "Geliefert", aber der Lesebeleg enthält stattdessen "Gelesen". Daher können Sie alle gelesenen Belege auf dieselbe Weise stapelweise löschen. Im Folgenden werden wir Ihnen die konkreten Schritte im Detail beibringen.

Batch Alle Lesebestätigungen löschen

1. Zu Beginn start Ihren Ausblick.
2. Rufen Sie dann den Outlook VBA-Editor über "Alt + F11" gemäß "So führen Sie VBA-Code in Outlook aus".
3. Öffnen Sie als Nächstes im neuen Fenster ein leeres Modul und geben Sie den folgenden Code ein.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Danach klicken Sie in die erste Unterroutine.
5. Drücken Sie abschließend die Taste „F5“.
6. Das Makro löscht sofort alle gelesenen Belege aus Ihrem Outlook.
7. Wenn es fertig ist, erhalten Sie eine Eingabeaufforderung über das Ergebnis, wie im folgenden Screenshot dargestellt.
8. Derzeit können Sie Ihre E-Mail-Ordner überprüfen. Alle gelesenen Belege sind verschwunden.

Outlook-Daten verteidigen

Obwohl die Outlook-Datei zugegebenermaßen anfällig für Beschädigungen ist, können wir Maßnahmen ergreifen, um sie zu schützen. Zum Beispiel sollten wir die Outlook-Datei klein halten, sie vor böswilligen Faktoren schützen und sie regelmäßig sichern. Zu guter Letzt sollten Sie ein leistungsfähiges externes PST-Reparaturwerkzeug vorbereiten, wie z DataNumen Outlook Repair. Dies hat große Auswirkungen auf die Reparatur beschädigtes Outlook Datei.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich SQL-Reparatur und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX