3 Methoden zum Importieren von E-Mails aus einem Windows-Ordner in Ihr Outlook

Möglicherweise haben Sie mehrere Outlook-E-Mails in Ihrem Windows-Ordner gespeichert. Wenn Sie sie nun wieder in einen Outlook-Ordner importieren möchten, wie können Sie dies tun? In diesem Artikel erfahren Sie drei Möglichkeiten.

Wie wir alle wissen, bietet Outlook eine integrierte Option - "Speichern unter" -, mit der Sie die E-Mails im Windows-Ordner speichern können. Es gibt jedoch keine Funktion, mit der Sie die exportierten E-Mails wieder zum Outlook-Ordner hinzufügen können. Wenn Sie die Outlook-E-Mails wieder in Outlook importieren möchten, wie können Sie dies realisieren? Im Folgenden werden wir Ihnen 3 Methoden beibringen. Sie können eine beliebige auswählen.

Methode 1: Drag & Drop zum Importieren

1. Zu Beginn müssen Sie auf den Windows-Quellordner zugreifen, in dem die Outlook-E-Mails gespeichert sind, die in Outlook importiert werden sollen.
2. Starten Sie dann Ihre Outlook-Anwendung.
3. Öffnen Sie als Nächstes den Outlook-Ordner, in den Sie die E-Mails importieren möchten.
4. Anschließend müssen Sie sowohl das Windows-Ordnerfenster als auch das Outlook-Fenster eingrenzen, bis Sie sie in der Zwischenzeit anzeigen können.
5. Danach können Sie im Windows-Ordner eine der Outlook-E-Mails auswählen und dann „Strg + A“ drücken, um alle auszuwählen.
6. Später können Sie die ausgewählten E-Mails wie im folgenden Screenshot in den sichtbaren Outlook-Ordner ziehen und dort ablegen:
7. Schließlich sehen Sie, dass alle Outlook-E-Mails aus dem Windows-Ordner in den Outlook-Ordner importiert wurden (siehe Abbildung unten):

Methode 2: Verwenden Sie "CreateItemFromTemplate" in VBA

1. Drücken Sie zunächst im Hauptfenster von Outlook die Tastenkombination „Alt + F11“.
2. Als Nächstes erhalten Sie Zugriff auf das Outlook VBA-Editorfenster.
3. Kopieren Sie dann den folgenden VBA-Code in ein leeres Modul.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. Anschließend können Sie im aktuellen Modulfenster die Taste F5 drücken, um das Makro zu starten.
5. Danach müssen Sie im Popup-Dialogfeld zum Windows-Quellordner navigieren.
6. Nachdem Sie den Quellordner ausgewählt haben, werden alle Outlook-Elemente in diesem Ordner in den vordefinierten Outlook-Ordner importiert.
7. Hinweis: Auf diese Weise sind die importierten E-Mails alle neuen E-Mails, die Sie nach Belieben verfassen können, wie im folgenden Screenshot dargestellt:

Methode 3: Verwenden Sie "OpenSharedItem" in VBA

1. Kopieren Sie wie bei Methode 2 die folgenden VBA-Codes in ein anderes Modul.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Führen Sie dann dieses Makro aus, indem Sie die Taste „F5“ drücken.
3. Wählen Sie als Nächstes den Quellordner aus.
4. Schließlich werden alle E-Mails wie im folgenden Bild importiert:

Vergleiche

Mittel zum Blockieren der PST-Datenbeschädigung

Wie wir alle wissen, ist Outlook mit einem integrierten Tool vorinstalliert. scanpstMeistens kann es kleinere Probleme lösen. Bei schwerwiegenden Problemen stößt das integrierte Tool jedoch an seine Grenzen. In diesem Fall empfiehlt es sich, auf ein leistungsfähigeres Tool zurückzugreifen, wie zum Beispiel … DataNumen Outlook Repair.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich SQL Server Korruption und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX