Jak rychle odstranit duplicitní příjemce z e-mailu aplikace Outlook pomocí VBA

Pokud přidáte skupiny kontaktů do pole „Komu“ aktuálního e-mailu, mohou mezi nimi být některé duplicitní. Tento článek vás naučí, jak pomocí VBA rychle odstranit duplicitní příjemce.

Pokud při psaní e-mailu nejen přidáváte kontakty, ale také skupiny kontaktů jako příjemce, někdy mohou existovat i duplikovaní příjemci, protože skupiny kontaktů jsou ve výchozím nastavení sbalené. V tomto případě, pokud chcete zjistit duplicitní, musíte nejprve rozšířit skupiny kontaktů a poté ručně porovnat příjemce, což bylo podrobně představeno v mém předchozím článku - “Jak odebrat duplicitní příjemce z e-mailů aplikace Outlook“. Bez jakýchkoli pochybností je to velmi zdlouhavé. Mnoho uživatelů tedy touží po rychlém způsobu odstranění duplicitních příjemců. V následujících bodech vás naučíme, jak to získat pomocí aplikace Outlook VBA.

Rychle odeberte duplicitní příjemce z e-mailu aplikace Outlook

1. Na prvním místě spusťte aplikaci Outlook.
2. Poté přepněte na kartu „Vývojář“ a klikněte na tlačítko „Visual Basic“ nebo jednoduše stiskněte klávesy „Alt + F11“.
3. Dále v okně „Microsoft Visual Basic pro aplikace“ můžete otevřít prázdný modul.
4. Následně zkopírujte a vložte následující kódy VBA do tohoto modulu.

Sub RemoveDuplicateRecipients()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact groups in "To" field
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend
 
    'Remove the duplicate recipients
    For i = objRecipients.Count To 1 Step -1
        For n = (i - 1) To 1 Step -1
            If objRecipients(i).Address = objRecipients(n).Address Then
               objRecipients(i).Delete
               Exit For
            End If
        Next
    Next
End Sub

5. Poté můžete přidat nový projekt VBA na panelu nástrojů Rychlý přístup v okně zprávy.
6. Později musíte nastavit nízkou úroveň zabezpečení maker aplikace Outlook.
7. Nakonec to můžete vyzkoušet.

• Nejprve stačí napsat e-mail jako obvykle.
• Poté přidejte skupiny kontaktů a kontakty do pole „Komu“.
• Dále můžete kliknout na tlačítko nového makra na panelu nástrojů Rychlý přístup.
• Aplikace Outlook najednou automaticky rozbalí skupiny kontaktů a poté odebere duplicitní příjemce.

Chraňte svá cenná data aplikace Outlook

Protože je aplikace Outlook náchylná ke zhroucení, jsou vaše data aplikace Outlook náchylná k poškození. Musíte tedy vyvinout velké úsilí k ochraně souboru aplikace Outlook. Nejprve musíte pravidelně zálohovat soubor PST. To usnadní poškozený PST opravit. Kromě toho byste si měli lépe připravit výkonný nástroj pro opravu, jako je DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně mdf opravit a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com