Jak rychle exportovat hlasovací statistiky z e-mailu aplikace Outlook do listu aplikace Excel

Pokud jste odeslali e-mail s hlasovacími tlačítky a poté, co vám příjemci odpovědí, můžete chtít spočítat a exportovat statistiky hlasování do listu aplikace Excel. V tomto příspěvku vás tedy naučíme, jak toho rychle dosáhnout.

Outlook je tak silný, že dokonce nabízí funkci „Hlasování“. Můj předchozí článek “Dovedné využití MS Outlook pro hlasování„… naučil, jak jej efektivně využívat. Také ve většině případů můžete po hlasování exportovat statistiky hlasování do listu aplikace Excel z nějakých důvodů, například chcete-li si statistiky vytisknout. Outlook to ale ve výchozím nastavení nepodporuje. Proto vás v následujícím textu naučíme, jak toho dosáhnout.

Exportujte statistiky hlasování v e-mailu do listu aplikace Excel

1. Hned na začátku spusťte aplikaci Outlook.
2. Poté byste měli v hlavním okně aplikace Outlook stisknout tlačítka „Alt + F11“.
3. Dále v okně „Microsoft Visual Basic for Applications“ byste měli povolit „Knihovnu objektů Microsoft Excel“. Klikněte na „Nástroje“ > „Odkazy“. V rozbalovacím dialogovém okně zaškrtněte políčko před položkou „Knihovna objektů Microsoft Excel“ a nakonec klikněte na tlačítko „OK“.
4. Poté můžete vložit nový modul nebo otevřít nepoužívaný modul.
5. Následně zkopírujte a vložte následující kódy VBA do tohoto modulu.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Poté pro lepší přístup bylo lepší přidat nové makro na panel nástrojů Rychlý přístup.
6. Nakonec to můžete vyzkoušet.

• Nejprve vyberte zdrojový e-mail, který obsahuje hlasovací tlačítka.
• Poté klikněte na tlačítko makra na panelu nástrojů Rychlý přístup.
• Po dokončení spuštění tohoto makra můžete procházet předdefinovanou místní složku, ve které uvidíte nový sešit aplikace Excel.
• Otevřete tento sešit aplikace Excel. Nyní uvidíte statistiku hlasování, která se zobrazí jako obrázek níže:

Nikdo nemůže důkladně odvrátit chyby aplikace Outlook

Přestože Outlook přichází s řadou funkcí, neexistuje žádná taková funkce, která by nám pomohla vyhnout se chybám aplikace Outlook. Chyby aplikace Outlook mohou způsobit všechny druhy faktorů. Pokud například Outlook opouštíte nesprávně, pravděpodobně utrpíte PST korupce. V takovém scénáři vám nezbývá než použít nějaké silné nástroje k záchraně vašeho souboru PST DataNumen Outlook Repair. Díky své vysoké míře obnovy si vysloužil spoustu sláva.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně zkorumpovaný mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com