Chcete-li hromadně exportovat více e-mailů aplikace Outlook do dokumentu s jedním slovem, můžete použít kód VBA uvedený v tomto článku. Může vám pomoci dokončit tento úkol během několika sekund.
V předchozím článku jsem někdy představil, jak převést e-mail aplikace Outlook na dokument Word - „2 Efektivní metody převodu e-mailu aplikace Outlook na dokument aplikace Word“. Oba dva prostředky uvedené v této strost bude bezmocný v případě, že chcete hromadně exportovat mnoho e-mailů do jednoho dokumentu aplikace Word. Proto vás zde naučíme jiným způsobem. Nyní čtěte dál, abyste to mohli složitě získat.
Dávkový export více e-mailů aplikace Outlook do jednoho Word dokumentu
- Start, spusťte aplikaci Outlook.
- Poté, co vstoupíte do hlavního okna Outlooku, musíte stisknout klávesy „Alt + F11“.
- Dále získáte přístup k editoru aplikace Outlook VBA, ve kterém byste měli otevřít prázdný modul.
- Následně zkopírujte níže uvedený kód VBA do otevřeného okna modulu.
Sub ExportMultipleEmails_OneWordDocument()
Dim objFileSystem As Object
Dim strTempFolder As String
Dim objSelection As Outlook.Selection
Dim objMail As Outlook.MailItem
Dim strFileName As String
Dim objWordApp As Word.Application
Dim objNewWordDocument As Word.Document
Dim objWordRange As Word.Range
Dim strWordDocument As String
Dim i As Long
'Create a temp folder
Set objFileSystem = CreateObject("Scripting.FileSystemObject")
strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
MkDir (strTempFolder)
On Error Resume Next
'Save each selected email as an individual Word document in a temp folder
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For Each objMail In objSelection
strFileName = objMail.Subject
'Remove the unsupported characters in email subject
strFileName = Replace(strFileName, "/", " ")
strFileName = Replace(strFileName, "\", " ")
strFileName = Replace(strFileName, ":", "")
strFileName = Replace(strFileName, "?", " ")
strFileName = Replace(strFileName, Chr(34), " ")
objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
Next
'Merge all the Word documents into a single document
Set objWordApp = CreateObject("Word.Application")
Set objNewWordDocument = objWordApp.Documents.Add
strWordDocument = Dir(strTempFolder & "\" & "*.doc")
i = 0
Do Until strWordDocument = ""
i = i + 1
Set objWordRange = objNewWordDocument.Range
With objWordRange
.Collapse wdCollapseEnd
If i > 1 Then
.InsertBreak wdSectionBreakNextPage
.End = objNewWordDocument.Range.End
.Collapse wdCollapseEnd
End If
.InsertFile strTempFolder & "\" & strWordDocument
End With
strWordDocument = Dir()
Loop
'Change the path as per your own needs
objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
objWordApp.Quit
'Delete the temp folder
objFileSystem.DeleteFolder (strTempFolder)
End Sub
- Poté je lepší přidat tento nový projekt VBA na panel nástrojů Rychlý přístup nebo na pás karet.
- Nakonec to můžete vyzkoušet.
- Na prvním místě vyberte více e-mailů aplikace Outlook.
- Poté vyhledejte a klikněte na nově přidané tlačítko makra.
- Po zobrazení výzvy „Dokončeno“ můžete procházet předdefinovanou místní složku a vyhledat nový dokument aplikace Word.
- Otevřete tento dokument, ve kterém uvidíte, že všechny vybrané e-maily byly exportovány.
Udržujte Mighty Recovery Tool poblíž
Bez ohledu na četné funkce nemůže být Outlook imunní vůči chybám. Pokud jste zvyklí nechat chyby osamocené, s jejich hromaděním, určitě dojde k selhání aplikace Outlook. V tomto okamžiku je zásadní opakovat se k mocnému a efektivnímu nástroji pro obnovení, jako je DataNumen Outlook Repair. Je dobře obeznámen s Oprava PST. Dokud s tím nebudete muset mít obavy o ztrátu dat aplikace Outlook.
Úvod autora:
Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně poškozený mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com