Jak vytvořit kalendář v listu aplikace Excel pomocí skriptu VBA

Excel má širokou škálu použití. V tomto článku vám ukážeme, jak vytvořit kalendář v listu pomocí makra.

Kromě ukládání a analýzy dat v Excelu jej můžete použít také k dokončení dalších úkolů. Můžete například shromažďovat informace pomocí aplikace Excel nebo si můžete své plánování poznamenat do listu. Dnes jsme našli nové využití. Kalendář můžete vytvořit v listu. Efekt můžete vidět na obrázku níže.

Do tohoto kalendáře můžete zadat některé úkoly. A funkce je stejná jako memorandum. Pomocí aplikace Excel budou tyto úkoly jasnější. Nyní postupujte podle pokynů v následující části a podívejte se, jak to funguje.

Vytvořte kalendář

1. Stisknutím klávesy „Alt + F11“ na klávesnici otevřete pracovní list.
2. A pak vložte nový modul do editoru jazyka.
3. Nyní kopírujeme následující kódy do nového modulu:

Sub Create_Monthly_Calender()
    Dim firstweekday As Integer, EndDay As Integer, _
    FirstWeekColumnIndex As Integer, AssignmentDate As Integer, _
    FirstCountNumber As Integer, SecondCountNumber As Integer, _
    LastDay As Range, objRange As Range, RowIndexofLastday As Integer, FirstCountforTargetRange As Integer, SecondCountforTargetRange As Integer

    firstday = InputBox("Input the year, month and the first day with this format: year/month/day")
    If firstday = "" Then Exit Sub


    Range("A1:G1").Merge
    Range("A1") = Year(firstday) & "." & Month(firstday)
    Range("A2") = "Sunday"
    Range("A2").AutoFill Destination:=Range("A2:G2"), Type:=xlFillDefault
    firstweekday = Application.WorksheetFunction.Weekday(firstday)
    Cells(3, firstweekday) = 1

    Select Case Month(firstday)
        Case 1, 3, 5, 7, 8, 10, 12
            EndDay = 31
        Case 4, 6, 9, 11
            EndDay = 30
        Case 2
            If (Year(firstday) Mod 4) = 0 And (Year(firstday) Mod 100) <> 0 Or ((Year(firstday) Mod 400) = 0) Then
                EndDay = 29
            Else
                EndDay = 28
            End If
    End Select

    For FirstWeekColumnIndex = 1 To (7 - firstweekday)
        Cells(3, firstweekday).Offset(0, FirstWeekColumnIndex) = Cells(3, firstweekday).Offset(0, FirstWeekColumnIndex - 1) + 1
    Next FirstWeekColumnIndex

    AssignmentDate = Range("G3") + 1
    For FirstCountNumber = 2 To 10 Step 2
        For SecondCountNumber = 0 To 6
            Cells(3, firstweekday).Offset(FirstCountNumber, 1 - firstweekday + SecondCountNumber) = AssignmentDate
            AssignmentDate = AssignmentDate + 1
            If Cells(3, firstweekday).Offset(FirstCountNumber, 1 - firstweekday + SecondCountNumber) = EndDay Then
                Exit For
            End If
        Next SecondCountNumber
        If Cells(3, firstweekday).Offset(FirstCountNumber, 1 - firstweekday + SecondCountNumber) = EndDay Then
            Exit For
        End If
    Next FirstCountNumber

    ’set format for the range
    With Range("A1")
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlCenter
        .Font.Size = 16
        .Font.Bold = True
        .Interior.Color = RGB(196, 202, 201)
    End With

    With Range("A2:G2")
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlCenter
        .Font.Bold = True
    End With

    For Each LastDay In ActiveSheet.UsedRange
        If LastDay = EndDay Then
            RowIndexofLastday = LastDay.Row
        End If
    Next

    For FirstCountforTargetRange = RowIndexofLastday To 3 Step -2
            With Range("A" & FirstCountforTargetRange, "G" & FirstCountforTargetRange)
                .HorizontalAlignment = xlCenter
                .VerticalAlignment = xlCenter
                .RowHeight = 20
            End With
    Next FirstCountforTargetRange

        For SecondCountforTargetRange = RowIndexofLastday + 1 To 4 Step -2
            With Range("A" & SecondCountforTargetRange, "G" & SecondCountforTargetRange)
                .HorizontalAlignment = xlCenter
                .VerticalAlignment = xlCenter
                .Font.Bold = True
                .RowHeight = 50
                .ColumnWidth = 12
            End With
    Next SecondCountforTargetRange

    Set objRange = Range("A1", "G" & (RowIndexofLastday + 1))
    With objRange.Borders
        .Color = vbBlack
        .Weight = xlThin
        .LineStyle = xlContinuous
    End With

    ActiveWindow.DisplayGridlines = False
    Cells(3, firstweekday).Offset(1, 0).Select
End Sub

Toto je velmi osamělé makro. Můžete jej ale přímo použít. A nemusíte to upravovat.

4. Poté stiskněte tlačítko „F5“ na klávesnici.
5. Ve vyskakovacím okně zadejte datum prvního dne ve formátu „Rok / Měsíc / Den“. „Den“ může být kterýkoli den v tomto měsíci, zde zadáme „1“.
6. Poté klikněte na tlačítko „OK“. Dále se vrátíte k editoru. Chcete-li zkontrolovat výsledek, můžete se vrátit do listu.

Kalendář se již v listu objevil. Kurzor bude umístěn do prázdné buňky prvního dne.

Na druhou stranu, pokud nejste spokojeni s formátem buněk, můžete také upravit kódy podle svých preferencí. S tímto kalendářem určitě zlepšíte efektivitu práce.

Excel není méně náchylný k selhání

Pokud Excel používáte často, nebude pro vás těžké zjistit, že se neustále poškozuje. Většinou problém vyřeší ukončení a opětovné spuštění Excelu. Někdy se však setkáte s vážným poškozením Excelu. A v tomto okamžiku můžete použít náš výkonný nástroj. opravit chybu dat Excel xlsxPomocí tohoto nástroje lze snadno vyřešit téměř všechny chyby.

Úvod autora:

Anna Ma je ​​expertem na obnovu dat v DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně opravit soubor Word docx a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com