2 způsoby hromadného odstranění všech kontaktů bez e-mailové adresy v aplikaci Outlook

Pokud zjistíte, že některé kontakty nemají v Outlooku žádnou e-mailovou adresu, můžete zpracovat každou složku kontaktů a všechny takové kontakty odstranit. V tomto příspěvku se s vámi podělíme o dva způsoby.

Možná máte ve svém Outlooku mnoho kontaktů a některé z nich nemají e-mailovou adresu. Pokud si myslíte, že již nejsou užitečné, musíte doufat, že smažete všechny kontakty bez e-mailové adresy. Standardním způsobem můžete použít „Okamžité vyhledávání“ k jejich nalezení a poté je ručně odstranit, jako je následující Metoda 1. Přesto je to trochu zdlouhavé. Proto vás v Metodě 2 naučíme další efektivnější způsob.

Metoda 1: Ruční odstranění po nalezení kontaktů bez e-mailové adresy

1. Pro začátek stiskněte klávesy „Ctrl + 3“ pro přístup k panelu „Kontakty“.
2. Poté klikněte do vyhledávacího pole.
3. Dále ve vznikajícím pásu „Hledat“ klikněte na „Všechny položky kontaktu“.
4. Následně klikněte na „Má adresu“ > „Má e-mailovou adresu“.
5. Poté bude do vyhledávacího pole přidáno kritérium „NOT e-mailové adresy:=[]“. Musíte odstranit „NOT“.
6. Následně budou uvedeny všechny kontakty bez e-mailové adresy.
7. Nyní byste měli vybrat kontakty ve výsledcích vyhledávání ručně, protože vaše skupiny kontaktů musí být také v seznamu.
8. Nakonec stiskněte tlačítko „Del“ pro smazání všech vybraných kontaktů.

Metoda 2: Dávkové odstranění všech kontaktů bez e-mailové adresy pomocí VBA

1. Nejprve klepnutím na „Alt + F11“ spusťte editor VBA v aplikaci Outlook.
2. Na nové obrazovce zkopírujte následující kód VBA do modulu.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Později klikněte na podprogram „BatchDeleteAllContactsWithoutEmailAddress“.
4. Nakonec stiskněte „F5“ pro spuštění tohoto makra.
5. Po dokončení obdržíte zprávu o výsledcích, jako je obrázek níže.
6. Všechny kontakty bez e-mailové adresy byly přesunuty do složky „Odstraněná pošta“.

Držte se daleko od všech potenciálních rizik

Aplikace Outlook může dojít k poškození v důsledku různých faktorů, jako jsou viry, uživatelské chyby, selhání softwaru a také poruchy hardwaru. Musíte se zdráhat zažít poškození aplikace Outlook, takže musíte mít všechna tato potenciální rizika na uzdě. Například musíte do počítače nainstalovat účinný antivirový software. Data Outlooku navíc musíte pravidelně zálohovat. V neposlední řadě si raději připravte robustní a spolehlivý opravný nástroj, jako je kupř DataNumen Outlook Repair. Může to opravit vaše poškozený PST soubor s lehkostí.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně SQL Server korupce a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com