Hur man snabbt hittar enstaka stycken i ditt Word-dokument

I det här inlägget vill vi visa dig det snabba sättet att hitta alla stycken med en mening i ditt Word-dokument via VBA.

Ibland kan vissa dokument ha mycket specifika krav på formatering och strukturer. Du kanske till exempel inte får ha stycken med bara en mening. Dessa stycken är inte svåra att känna igen, men det tar tid, särskilt det är ett långt dokument.

Idag erbjuder vi dig det snabba sättet att specificera alla stycken med en mening i ditt dokument.

Hitta alla stycken med en mening i ett dokument

1. För det första räknar Word en period som en mening. Så om det finns ord som ”Mr.” eller ”Ms”, Word betraktar det som en mening. För att utesluta en sådan distraktion måste du byta ut "Mr." med ”Mr”. Och när du hittar avsnittet i en enda mening kan du ändra tillbaka dem. För att ersätta ord kan du hänvisa till den här länken: Hur du hittar och ersätter flera objekt i ditt Word-dokument
2. För det andra, tryck på “Alt + F11” för att utlösa VBA-redigeraren.
3. Klicka sedan på “Normal” -projektet.
4. Klicka på fliken "Infoga" i menyraden och välj "Modul" i dess rullgardinsmeny.
5. Nästa dubbelklicka på modulen för att öppna den.
6. Klistra in följande koder på modulen:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Sist men inte minst, klicka på "Kör" -knappen eller tryck på "F5".

Du kommer att få en sådan meddelandefält som berättar att jobbet är klart.

Hitta alla stycken med en mening i flera dokument

1. Till att börja med måste du lägga alla måldokument i en mapp.
2. Installera och kör sedan böljande makro:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. I fönstret "Bläddra" öppnar du den mapp där du lagrar dokument och klickar på "OK".

Makrot markerar sedan alla stycken med en mening och lämnar dokument öppna. Om ett dokument inte innehåller ett stycke med en mening kommer det att stängas. Dessutom finns det en meddelandefält som anger antalet stycken med en mening i varje dokument.

Hantera dataförlusthändelse

Användarfel och plötsligt strömavbrott kan leda till att Word dör. Medan ett kollapsat ord inte bara kan påverka det dagliga arbetet utan också leda till doc skadaDetta är inte på något sätt den mest irriterande delen av en datakatastrof. Det är bättre att skaffa ett reparationsverktyg för att återställa data omedelbart.

Författarintroduktion:

Vera Chen är en dataåterställningsexpert i DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive återhämta sig excel och pdf reparera programvaruprodukter. För mer information besök www.datanumen.com