Så här exporterar du snabbt en Outlook-mapp med alla undermappar och objekt till en Windows-mapp

Ibland kanske du vill gruppexportera en Outlook-mapp med alla undermappar och objekt till en Windows-mapp. Denna artikel kommer att lära dig en sådan metod som använder Outlook VBA.

När du vill exportera en Outlook-mapp till en lokal enhet med alla objekt i samma mappstruktur, tar du mycket tid om du väljer att spara och exportera manuellt. Varför använder du dig inte av andra metoder, t.ex. exportverktyg eller VBA-koder? Här kommer vi att avslöja en sådan bit VBA-kod för dig. Det gör att du kan uppnå det som en vind.

Exportera alla undermappar och objekt i en Outlook-mapp till en Windows-mapp

1. Starta ditt Outlook-program redan från början.
2. Tryck sedan på ”Alt + F11” -tangenterna i huvudfönstret i Outlook.
3. Därefter kommer fönstret "Microsoft Visual Basic for Applications" att dyka upp.
4. Därefter måste du öppna en tom modul och kopiera följande VBA-koder till den.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Därefter måste du se till att din Outlook tillåter makron i makroinställningarna.
6. Så småningom kan du prova.

• Först tillbaka till det nya makrofönstret.
• Klicka sedan på "ExportFolderWithAllItems" underrutin.
• Tryck sedan på F5-tangenten för att köra detta makro.
• Därefter måste du välja en specifik mapp.
• Slutligen, när du får ett meddelande som säger "Komplett" kan du komma åt den fördefinierade lokala mappen. Du hittar alla objekt har sparats i samma mappstruktur.

Förhindra dataförlust från Outlook-kraschar

Du har kanske någonsin stött på många Outlook-krascher. För det mesta, efter en omstart, fungerar Outlook som vanligt. Det finns dock också fall där vår PST-fil kan bli skadad. Då bör du göra ditt bästa för att återställa dina PST-data, till exempel genom att använda ett erfaret verktyg som DataNumen Outlook Repair. Det kan fixa Outlook fel och extrahera data från komprometterad PST-fil utan att svettas.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive SQL Server reparation och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com