Så här exporterar du snabbt alla bildbilagor i ett Outlook-e-postmeddelande till ett Excel-arbetsblad

Om du snabbt vill exportera alla bildbilagor i ett Outlook-e-postmeddelande till ett Excel-kalkylblad kan du läsa den här artikeln. Här visar vi dig ett mer effektivt sätt än att manuellt exportera.

När du får ett e-postmeddelande som innehåller en mängd bildbilagor, och vill använda dem för att skapa en rapport i Excel, måste du leta efter ett sätt att exportera dessa bilder till ett Excel-ark i omgångar. Nu ska vi presentera en sådan metod för dig i det följande.

Exportera alla bildbilagor i ett e-postmeddelande till ett Excel-arbetsblad

1. Till att börja med, öppna din Outlook-applikation på normalt sätt.
2. Tryck sedan på "Alt + F11" -tangenterna i Outlook-fönstret, vilket visar fönstret "Microsoft Visual Basic for Applications".
3. På den här skärmen måste du öppna en modul som inte används eller infoga en ny direkt.
4. Därefter bör du kopiera biten av VBA-koden nedan till den här modulen.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Därefter kan du avsluta makrot.
6. Gå sedan till "File"> "Options"> "Quick Access Toolbar" för att lägga till detta makro i Quick Access Toolbar.
7. Slutligen kan du prova detta makro just nu.

• Välj eller öppna ett källmeddelande.
• Klicka sedan på makroknappen i verktygsfältet Snabbåtkomst.
• När makrot är klart får du ett Excel-kalkylblad, som visas på följande skärmdump:

Skydda Outlook-filen från att bli korrupt

Det är känt att Outlook är utsatt för korruption. Därför bör vi förstå hur vi kan skydda korruption i Outlook-form. För det första, för att blockera virusattacker, är det nödvändigt att installera antivirusprogram och aldrig ladda ner okänd bilaga. Dessutom är det bättre för oss att få tag i ett kraftfullt reparationsverktyg, till exempel DataNumen Outlook RepairDet kan erbjuda den mest effektiva lösningen vid Outlook korruption.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive SQL-återhämtning och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com